【EA開発入門】RCIで自動売買ロジックを作る方法｜RCI Multi Signal対応サンプルコードつき

//+------------------------------------------------------------------+
//|                                                      10_RCI.mq4 |
//|                                Copyright © 2020-2025 ぷろぐらむFX |
//|                                             https://fx-prog.com/ |
//|使い方：
//|パラメータ設定と、OnTick内「新規注文判断」「TP/SL判断」「決済注文判断」に
//|当サイトのロジックを埋め込むだけでEA化できます。
//+------------------------------------------------------------------+


#property copyright "Copyright © 2020-2025 ぷろぐらむFX"
#property link      "https://fx-prog.com/"
#property version   "1.00"
#property strict


input double Lots = 0.01;              //ロット
input int TP = 100;                    //利確(pips)
input int SL = 50;                     //損切り(pips)
//***【パラメータ設定↓】***//
input int RCI_KIKAN1 = 9;
input int RCI_KIKAN2 = 26;
input int RCI_KIKAN3 = 52;
input int RCI_VIEW_CNT = 3;
input int RCI_KAI = -80;
input int RCI_URI = 80;
//***【パラメータ設定↑】***//

string Ea_Name = WindowExpertName();   //チャート上のEA名称を取得(オーダーコメントに使用)

double PipValue;                       //ブローカー桁数に対応した Point 補正
datetime prevtime;                     //ローソク足時間保持用

//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit(){

   //デジットチェック
   if (Digits == 3 || Digits == 5){
      PipValue = Point * 10;   // 例: EURUSD 1.23456 → 1pip = 0.00010
   }else{
      PipValue = Point;        // 例: USDJPY 123.45 → 1pip = 0.01
   }

   return(INIT_SUCCEEDED);
}
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason){

}
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick(){

   int total = OrdersTotal();    //ポジショントータル数をセット  
   int ea_order_Type = -1; //0:OP_BUY  1:OP_SELL
   double ea_order_stop_price = 0; //ストップロスレート
   double ea_order_good_price = 0; //利確レート

   //新しい足ができた時だけやる
   if(Time[0] != prevtime){
      prevtime = Time[0];
   }else{
      return;
   }

   //ポジションがない場合はエントリー判定
   if(total == 0){

      bool openBuy  = false;    //買い新規注文判断
      bool openSell = false;    //売り新規注文判断
      
//***【新規注文判断↓】***//
// RCI Multi Signal を利用したサイン判定
bool isBullRCI_S = false;
bool isBearRCI_S = false;

// RCI値取得
double rciS = GetRCI_MS(0, 1);
double rciM = GetRCI_MS(1, 1);
double rciL = GetRCI_MS(2, 1);

double rciM_prev = GetRCI_MS(1, 2);
double rciL_prev = GetRCI_MS(2, 2);

double slopeM = rciM - rciM_prev;
double slopeL = rciL - rciL_prev;

// -----------------------------
//  BUY条件（緩和版）
// -----------------------------
bool condBuy =
(
    rciS <= RCI_KAI            // 短期が売られすぎ
    &&
    (rciM > rciM_prev)         // 中期が上向きならOK（クロス不要）
    &&
    slopeM > 1                 // 傾きの最低強度
    &&
    slopeL > -5                // 長期が“弱い下落”まで許可
);

if(condBuy) isBullRCI_S = true;

// -----------------------------
//  SELL条件（緩和版）
// -----------------------------
bool condSell =
(
    rciS >= RCI_URI            // 短期が買われすぎ
    &&
    (rciM < rciM_prev)         // 中期が下向きならOK
    &&
    slopeM < -1                // 傾き（強度）緩め
    &&
    slopeL < 5                 // 長期が“弱い上昇”まで許可
);

if(condSell) isBearRCI_S = true;

//***【新規注文判断↑】***//


      //参照するサンプルEAの買いエントリーフラグをセットしてください
      if(isBullRCI_S){
         openBuy =true;
         ea_order_Type = OP_BUY;
      //参照するサンプルEAの売りエントリーフラグをセットしてください      
      }else if(isBearRCI_S){
         openSell =true;
         ea_order_Type = OP_SELL;
      }

//***【TP/SL判断↓】***//
// TP/SLを変更したい場合はこの部分を変更してください。
      if(openBuy){
         ea_order_stop_price = Ask - SL * PipValue;
         ea_order_good_price = Ask + TP * PipValue;
      }else if(openSell){
         ea_order_stop_price = Bid + SL * PipValue;  
         ea_order_good_price = Bid - TP * PipValue;   
      }
//***【TP/SL判断↑】***//

      if(ea_order_Type > -1){
         funcOrder_Send(ea_order_Type,ea_order_stop_price,ea_order_good_price,Lots,Ea_Name,777,0);
      }
      
   //ポジションがある場合は決済判定   
   }else{

//***【決済注文判断↓】***//
// ※今回サンプルでは RCI での決済条件は設定しません。
// 追加したい場合はここに条件を記述してください。
//***【決済注文判断↑】***//

   }

   return;
}


//+------------------------------------------------------------------+
//| ★ RCI Multi Signal 値取得 共通関数（新規追加）                  |
//+------------------------------------------------------------------+
double GetRCI_MS(int buffer, int shift)
{
   double v = iCustom(NULL, 0,
                      "RCI-Multi-Signal",
                      RCI_VIEW_CNT,     // 1〜3本表示
                      RCI_KIKAN1,
                      RCI_KIKAN2,
                      RCI_KIKAN3,
                      true,             // Signal_On
                      buffer,
                      shift);

   if(v == EMPTY_VALUE) return 0;
   return v;
}


//★★★★★★★★★★★★★★★★★★★★ ここから下は共通関数 ★★★★★★★★★★★★★★★★★★★★
//+------------------------------------------------------------------+
//|【関数】新規注文関数
//|
//|【引数】 orderType:売買(0=BUY, 1=SELL)
//|【引数】 sl:損切り価格  tp:利確価格
//|【引数】 lots:取引ロット数
//|【引数】 orderComment:オーダーコメント
//|【引数】 magic:マジックNo
//|【引数】 maxSpreadPips: 許容スプレッド[Point] (0=制限なし)
//|
//|【戻値】true=成功 false=失敗
//+------------------------------------------------------------------+
bool funcOrder_Send(int orderType, double sl, double tp, double lots,
                    string orderComment, int magic, int maxSpreadPoints){
   int    ticket = -1;
   double price  = 0;
   color  clr    = clrNONE;
   double spread = 0;

   // 最大10回リトライ
   for(int retry=0; retry<10; retry++)
   {
      RefreshRates();
      
      // スプレッド取得（MT4表示と同じポイント単位）
      spread = MarketInfo(Symbol(), MODE_SPREAD);

      // スプレッドチェック（maxSpreadPoints=0 の場合はスキップ）
      if(maxSpreadPoints > 0 && spread > maxSpreadPoints){
         Print("スプレッド拡大中(", spread,
               "ポイント) → 待機中 (リトライ=", retry+1, ")");
         Sleep(2000);
         continue;
      }

      // エントリー価格と色を決定
      if(orderType == OP_BUY){
         price = Ask;
         clr   = clrBlue;
      }else if(orderType == OP_SELL){
         price = Bid;
         clr   = clrRed;
      }

      ticket = OrderSend(Symbol(), orderType, lots, price,
                         20, sl, tp, orderComment, magic, 0, clr);

      if(ticket > 0){
         Print("新規注文成功! チケットNo=", ticket,
               " レート=", price, " Lots=", lots,
               " スプレッド=", spread, "ポイント");
         return true;
      }else{
         int err = GetLastError();
         Print("新規注文失敗 エラーNo=", err,
               " リトライ回数=", retry+1);
         Sleep(2000);
      }
   }

   return false;
}
 

double rci_short = iCustom(NULL,0,"RCI-Multi-Signal",9,26,52,3,0,1);
double rci_middle = iCustom(NULL,0,"RCI-Multi-Signal",9,26,52,3,1,1);
double rci_long = iCustom(NULL,0,"RCI-Multi-Signal",9,26,52,3,2,1);