MT4でストキャスティクスEAを作成｜無料MQL4サンプルコード解説

//+------------------------------------------------------------------+
//|                                                08_Stochastic.mq4 |
//|                                Copyright © 2020-2025 ぷろぐらむFX |
//|                                             https://fx-prog.com/ |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2020-2025 ぷろぐらむFX"
#property link      "https://fx-prog.com/"
#property version   "1.00"
#property strict


input double Lots = 0.01;              //ロット
input int TP = 100;                    //利確(pips)
input int SL = 100;                    //損切り(pips)
//***【パラメータ設定↓】ストキャスティクス***//
input int STOCHAS_K_KIKAN = 5;         //%K期間
input int STOCHAS_D_KIKAN = 3;         //%D期間
input int STOCHAS_SLOW = 3;            //スローイング
input int STOCHAS_KAI = 20;            //買いポイント(設定値以下のクロスで買い)
input int STOCHAS_URI = 80;            //売りポイント(設定値以上のクロスで売り)
//***【パラメータ設定↑】ストキャスティクス***//

string Ea_Name = "Stochastic";               //オーダーコメントに使用

double PipValue;                       //ブローカー桁数に対応した Point 補正
datetime prevtime;                     //ローソク足時間保持用
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit(){

   //デジットチェック
   if (Digits == 3 || Digits == 5){
      PipValue = Point * 10;   // 例: EURUSD 1.23456 → 1pip = 0.00010
   }else{
      PipValue = Point;        // 例: USDJPY 123.45 → 1pip = 0.01
   }

   return(INIT_SUCCEEDED);
}
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason){

}
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick(){

   int total = OrdersTotal();    //ポジショントータル数をセット  
   int ea_order_Type = -1; //0:OP_BUY  1:OP_SELL
   double ea_order_stop_price = 0; //ストップロスレート
   double ea_order_good_price = 0; //利確レート

   //新しい足ができた時だけやる
   if(Time[0] != prevtime){
      prevtime = Time[0];
   }else{
      return;
   }

   //ポジションがない場合はエントリー判定
   if(total == 0){

      bool openBuy  = false;    //買い新規注文判断
      bool openSell = false;    //売り新規注文判断
      
//***【新規注文判断↓】***//

      bool isBullStochas_S = false;
      bool isBearStochas_S = false;
      // ストキャス値（1本前と2本前の %Kと%D）
      double K1 = iStochastic(NULL,0,STOCHAS_K_KIKAN,STOCHAS_D_KIKAN,STOCHAS_SLOW,MODE_SMA,STO_LOWHIGH,MODE_MAIN,1);
      double D1 = iStochastic(NULL,0,STOCHAS_K_KIKAN,STOCHAS_D_KIKAN,STOCHAS_SLOW,MODE_SMA,STO_LOWHIGH,MODE_SIGNAL,1);
      double K2 = iStochastic(NULL,0,STOCHAS_K_KIKAN,STOCHAS_D_KIKAN,STOCHAS_SLOW,MODE_SMA,STO_LOWHIGH,MODE_MAIN,2);
      double D2 = iStochastic(NULL,0,STOCHAS_K_KIKAN,STOCHAS_D_KIKAN,STOCHAS_SLOW,MODE_SMA,STO_LOWHIGH,MODE_SIGNAL,2);
             
      //ゴールデンクロス & 買いゾーン
      if(K2 < D2 && K1 > D1 && K1 < STOCHAS_KAI) 
      {
         isBullStochas_S=true;
      }
      //デッドクロス & 売りゾーン 
      else if(K2 > D2 && K1 < D1 && K1 > STOCHAS_URI)
      {
         isBearStochas_S=true;
      }

//***【新規注文判断↑】***//

      //参照するサンプルEAの買いエントリーフラグをセットしてください
      if(isBullStochas_S){
         openBuy =true;
         ea_order_Type = OP_BUY;
      //参照するサンプルEAの売りエントリーフラグをセットしてください      
      }else if(isBearStochas_S){
         openSell =true;
         ea_order_Type = OP_SELL;
      }

//***【TP/SL判断↓】***//
      if(openBuy){
         ea_order_stop_price = Ask - SL * PipValue;
         ea_order_good_price = Ask + TP * PipValue;
      }else if(openSell){
         ea_order_stop_price = Bid + SL * PipValue;  
         ea_order_good_price = Bid - TP * PipValue;   
      }
//***【TP/SL判断↑】***//

      if(ea_order_Type > -1){
         funcOrder_Send(ea_order_Type,ea_order_stop_price,ea_order_good_price,Lots,Ea_Name,777,0);
      }
   }

   return;
}


//★★★★★★★★★★★★★★★★★★★★ ここから下は共通関数 ★★★★★★★★★★★★★★★★★★★★
//+------------------------------------------------------------------+
//|【関数】新規注文関数
//|
//|【引数】 orderType:売買(0=BUY, 1=SELL)
//|【引数】 sl:損切り価格  tp:利確価格
//|【引数】 lots:取引ロット数
//|【引数】 orderComment:オーダーコメント
//|【引数】 magic:マジックNo
//|【引数】 maxSpreadPips: 許容スプレッド[Point] (0=制限なし)
//|
//|【戻値】true=成功 false=失敗
//+------------------------------------------------------------------+
bool funcOrder_Send(int orderType, double sl, double tp, double lots,
                    string orderComment, int magic, int maxSpreadPoints){
   int    ticket = -1;
   double price  = 0;
   color  clr    = clrNONE;
   double spread = 0;

   // 最大10回リトライ
   for(int retry=0; retry<10; retry++)
   {
      RefreshRates();
      
      // スプレッド取得（MT4表示と同じポイント単位）
      spread = MarketInfo(Symbol(), MODE_SPREAD);

      // スプレッドチェック（maxSpreadPoints=0 の場合はスキップ）
      if(maxSpreadPoints > 0 && spread > maxSpreadPoints){
         Print("スプレッド拡大中(", spread,
               "ポイント) → 待機中 (リトライ=", retry+1, ")");
         Sleep(2000);
         continue;
      }

      // エントリー価格と色を決定
      if(orderType == OP_BUY){
         price = Ask;
         clr   = clrBlue;
      }else if(orderType == OP_SELL){
         price = Bid;
         clr   = clrRed;
      }

      ticket = OrderSend(Symbol(), orderType, lots, price,
                         20, sl, tp, orderComment, magic, 0, clr);

      if(ticket > 0){
         Print("新規注文成功! チケットNo=", ticket,
               " レート=", price, " Lots=", lots,
               " スプレッド=", spread, "ポイント");
         return true;
      }else{
         int err = GetLastError();
         Print("新規注文失敗 エラーNo=", err,
               " リトライ回数=", retry+1);
         Sleep(2000);
      }
   }

   return false;
}