エラー／リトライを考慮した新規・変更・決済関数(処理)

//+------------------------------------------------------------------+
//|【関数】新規注文関数
//|
//|【引数】 ea_order_entry_Type:売買(0:買 1:売)
//|【引数】 ea_order_stop_price:損切値  ea_order_good_price:利確値
//|【引数】 orderComment:オーダーコメント    ea_order_MagicNo:マジックNo
//|
//|【戻値】True:成功 False:失敗
//|
//|
bool funcOrder_Send(int ea_order_entry_Type, double ea_order_stop_price, double ea_order_good_price,string orderComment,int ea_order_MagicNo,int entrySpread)
{
   
   int order_resend_num;        // エントリー試行回数
   int ea_ticket_res;           // チケットNo
   double ea_order_entry_price; // エントリーレート
   color order_Color;
   bool kekka;
   
   kekka=false;
   
/////////ロット数確認領域/////////
   
   double Lot = 1;   // ロット[0.01単位]
   //double Lot = funcLotGet(200,10),  // ロット[0.01単位](証拠金200%維持、FXTFは最大10Lot)
/////////ロット数計算領域/////////
   
   
   for( order_resend_num = 0; order_resend_num < 10; order_resend_num++ ) {    // エントリー試行回数上限:10回
   
      //スプレッドがentrySpread未満の場合のみ新規注文する(2銭未満にしたい場合は20にする)
      if(MarketInfo(NULL,MODE_SPREAD) < entrySpread){
   
         if(ea_order_entry_Type == OP_BUY){   
            ea_order_entry_price = Ask;               // 現在の買値でエントリー
            order_Color = clrBlue;
         }else if(ea_order_entry_Type == OP_SELL){        
            ea_order_entry_price = Bid;               // 現在の売値でエントリー
            order_Color = clrRed;            
         }
   
         ea_ticket_res = OrderSend(   // 新規エントリー注文
            NULL,                     // 通貨ペア
            ea_order_entry_Type,      // オーダータイプ[OP_BUY / OP_SELL]
            Lot,                      // ロット数
            ea_order_entry_price,     // オーダープライスレート
            20,                       // スリッページ
            ea_order_stop_price,      // ストップレート
            ea_order_good_price,      // リミットレート
            orderComment,             // オーダーコメント
            ea_order_MagicNo,         // マジックナンバー
            0,                        // オーダーリミット時間
            order_Color               // オーダーアイコンカラー
            );
            
         if ( ea_ticket_res == -1) { 
            Print("エントリー失敗 エラーNo=",GetLastError()," リトライ回数=",order_resend_num+1);
               
            Sleep(5000);                                           // msec待ち
            RefreshRates();                                        // レート更新
      
         } else {    // 注文約定
            Print("新規注文約定。 レート:",ea_order_entry_price," チケットNo=",ea_ticket_res," オーダーマジックNo=",ea_order_MagicNo);
               
            Sleep(500);                                           // 500msec待ち
            kekka=true;
            break;
         }
   
      }else{
          Print("スプレッド拡大中(銭)=",MarketInfo(NULL,MODE_SPREAD) / 10," リトライ回数=",order_resend_num+1);
             
          Sleep(5000);                                           // msec待ち
          RefreshRates();                                        // レート更新
      }
   
   }
   return kekka;   
}
//+------------------------------------------------------------------+
//|【関数】トレール(変更注文)関数
//|
//|【引数】 ea_order_stop_price:損切値  ea_order_good_price:利確値
//|
//|【戻値】True:成功 False:失敗
//|
//|    
bool funcOrder_Modify(double ea_order_stop_price, double ea_order_good_price)
{
   bool kekka,OrderKekka;
   int total,order_resend_num,errorcode;
   
   kekka=false;
      
   for( order_resend_num = 0; order_resend_num < 20; order_resend_num++ ) {   
      
      total=OrdersTotal();
         
      if(total >0 && OrderSelect(0,SELECT_BY_POS,MODE_TRADES)==true){
         OrderKekka = OrderModify(OrderTicket(),OrderOpenPrice(),ea_order_stop_price,ea_order_good_price,0,clrYellow);
   
         if(OrderKekka==false){
            errorcode = GetLastError();
            
            Print("変更注文失敗 エラーNo=",errorcode," リトライ回数=",order_resend_num+1," SL=",ea_order_stop_price,"TP=",ea_order_good_price);
               
               
            //損切り・利確値が不正な場合は微調整する
            if(errorcode==ERR_INVALID_STOPS){
               if(OrderType() == OP_BUY){
                  ea_order_stop_price = ea_order_stop_price - 10 * Point;
                  ea_order_good_price = ea_order_good_price + 10 * Point;
               }else if(OrderType() == OP_SELL){
                  ea_order_stop_price = ea_order_stop_price + 10 * Point;
                  ea_order_good_price = ea_order_good_price - 10 * Point;            
               }
            }
               
            RefreshRates();
            Sleep(5000);
         }else{
            Print("変更注文完了。 SL=",ea_order_stop_price," TP=",ea_order_good_price);
            
            kekka=true;
            break;
         }
      }
   }
      
   return kekka;   
}
   
//+------------------------------------------------------------------+
//|【関数】決済関数
//|
//|【引数】 kessaiSpread:許容する決済時のスプレッド
//|
//|【戻値】True:成功 False:失敗
//|
//|
bool funcOrder_Close(int kessaiSpread)
{
   bool kekka,OrderKekka;
   int total,order_resend_num;
   double ea_order_entry_price; // エントリーレート
   color order_Color;
      
   kekka=false;
   
   for(order_resend_num = 0; order_resend_num < 100; order_resend_num++ ) {
      if(MarketInfo(NULL,MODE_SPREAD) < kessaiSpread){
   
         total=OrdersTotal();
            
         if(total >0 && OrderSelect(0,SELECT_BY_POS,MODE_TRADES)==true){
   
            if(OrderType() == OP_BUY){   
               ea_order_entry_price = Bid;               // 現在の売値で決済
               order_Color = clrLightBlue;
            }else if(OrderType() == OP_SELL){
               ea_order_entry_price = Ask;               // 現在の買値で決済
               order_Color = clrLightPink;            
            }
   
            OrderKekka = OrderClose(OrderTicket(),OrderLots(),ea_order_entry_price,10,order_Color);
   
            if(OrderKekka==false){
               Print("決済失敗 エラーNo=",GetLastError()," リトライ回数=",order_resend_num+1);
                  
               RefreshRates();
               Sleep(1000);
            }else{
               Print("決済注文約定。 レート=",ea_order_entry_price);
               
               kekka=true;
               break;
            }
         }
      }else{
          Print("スプレッド拡大中(銭)=",MarketInfo(NULL,MODE_SPREAD) / 10," リトライ回数=",order_resend_num+1);
             
          Sleep(5000);                                           // msec待ち
          RefreshRates();                                        // レート更新
      }
   }
   return kekka;   
}