【MQL4】雇用統計日にEAを自動停止する関数｜経済指標回避フィルターの作り方

//+------------------------------------------------------------------+
//|【関数】雇用統計判定用関数
//|
//|【引数】 なし
//|
//|【戻値】True:雇用統計日 False:雇用統計日ではない

bool IsKoyouToukeiHantei(){
#define ONEDAY (3600 * 24)
// 曜日
#define SUNDAY 0
#define MONDAY 1
#define TUESDAY 2
#define WEDNESDAY 3
#define THURSDAY 4
#define FRIDAY 5
#define SATURDAY 6

MqlDateTime current;
current.year = Year();
current.mon = Month();
current.day = Day();
current.hour = 12;
current.min = 0 ;
current.sec = 0;
   TimeToStruct(StructToTime(current), current);

   //2013年10月と11月は例外
   if(current.year == 2013 && (current.mon == 10 || current.mon == 11)){
      // 2013年10月は22日に発表
      if( current.mon == 10 && current.day == 22 )
      {
         return true;
      }
      // 2013年11月は8日に発表
      if( current.mon == 11 && current.day == 8 )
      {
         return true;
      }
      return false;
   }

   //2025年10月〜12月は例外
   if(current.year == 2025 && (current.mon == 10 || current.mon == 11 || current.mon == 12)){
      // 2025年10月は発表されず
      if( current.mon == 10)
      {
         return false;
      }
      // 2025年11月は20日に発表
      if( current.mon == 11 && current.day == 20 )
      {
         return true;
      }
      // 2025年12月は16日に発表
      if( current.mon == 12 && current.day == 16 )
      {
         return true;
      }  
      
      
      return false;         
   }


   //2026年2月は例外
   if(current.year == 2026 && (current.mon == 2)){
      // 2026年2月は11に発表
      if(current.day == 11 )
      {
         return true;
      }  
      return false;
           
   }

   if( current.mon == 1 )
   {
      // 1月は４～１０日の金曜日が雇用統計で確定。
      if( 4 <= current.day && current.day <= 10 && current.day_of_week == FRIDAY )
      {
         return true;
      }
   }
   else if( current.mon == 7 && (current.day == 2 || current.day == 3) && current.day_of_week == THURSDAY)
   {
      // 7/4は独立記念日の為、重なった場合は木曜日にずれる。
      // 7/3が金曜日の場合も振替休日のためずれる。
      return true;
   }
   else if( current.mon == 7 && (current.day == 3 || current.day == 4) && current.day_of_week == FRIDAY)
   {
      return false;
   }
   else if(  1 <= current.day && current.day <= 10 && (current.day_of_week == THURSDAY || current.day_of_week == FRIDAY ))
   {
      //前の月の12日を含む週から3番目
      MqlDateTime beforeMonth;
      beforeMonth.year = current.year;
      beforeMonth.mon = current.mon - 1;
      beforeMonth.day = 12;
      beforeMonth.hour = 12;
      beforeMonth.min = 0;
      beforeMonth.sec = 0;

      datetime beforeMonthTime = StructToTime(beforeMonth);
      TimeToStruct( beforeMonthTime, beforeMonth);

      datetime emplymentDay = beforeMonthTime + (5 - TimeDayOfWeek(beforeMonthTime) + 21) * ONEDAY;

      if( current.day == TimeDay(emplymentDay) )
      {
         return true;
      }
   }
   return false;
}

//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
{

   // 雇用統計日の判定
   // Hour() はMT4サーバー時間です。利用業者のサーバー時間に合わせて調整してください。
   if(IsKoyouToukeiHantei() == true && Hour() >= 10 && Hour() <= 16){
      return; // 雇用統計日の指定時間帯は新規売買ロジックを実行しない
   }

   // 通常ロジック
   // ...
}