ブレイクアウトEAの作り方｜高値更新ロジックをMQL4で実装【サンプルコード付き】

//+------------------------------------------------------------------+
//|                                                  32_BreakOut.mq4 |
//|                                    Copyright © 2020-2026 ぷろぐらむFX |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2020-2026 ぷろぐらむFX"
#property link      "https://www.mql5.com"
#property version   "1.00"
#property strict


input double Lots = 0.01;              //ロット
input int TP = 30;                    //利確(pips)
input int SL = 30;                    //損切り(pips)
//***【パラメータ設定↓】***//
// ここにパラメータ設定を追加してください
input int BreakPeriod = 22;               // ブレイク判定本数
input bool SameDirectionBlock = true;     // 同一方向の再エントリー禁止
int lastDirection = 0;   // 1=BUY -1=SELL
//***【パラメータ設定↑】***//

string Ea_Name = WindowExpertName();   //チャート上のEA名称を取得(オーダーコメントに使用)

double PipValue;                       //ブローカー桁数に対応した Point 補正
datetime prevtime;                     //ローソク足時間保持用
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit(){

   //デジットチェック
   if (Digits == 3 || Digits == 5){
      PipValue = Point * 10;   // 例: EURUSD 1.23456 → 1pip = 0.00010
   }else{
      PipValue = Point;        // 例: USDJPY 123.45 → 1pip = 0.01
   }

   return(INIT_SUCCEEDED);
}
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason){

}
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick(){

   int total = OrdersTotal();    //ポジショントータル数をセット  
   int ea_order_Type = -1; //0:OP_BUY  1:OP_SELL
   double ea_order_stop_price = 0; //ストップロスレート
   double ea_order_good_price = 0; //利確レート

   //新しい足ができた時だけやる
   if(Time[0] != prevtime){
      prevtime = Time[0];  
   }else{
      return;
   }

   //ポジションがない場合はエントリー判定
   if(total == 0){

      bool openBuy  = false;    //買い新規注文判断
      bool openSell = false;    //売り新規注文判断
      
//***【新規注文判断↓】***//
      // 2本前までの最高値を取得
      double highestPrice = High[
         iHighest(NULL, 0, MODE_HIGH, BreakPeriod, 2)
      ];
      
      double lowestPrice = Low[
         iLowest(NULL, 0, MODE_LOW, BreakPeriod, 2)
      ];
      
      // 1本前がブレイクしたか判定
      bool breakUp = (Close[1] > highestPrice);
      bool breakDown = (Close[1] < lowestPrice);

      if(SameDirectionBlock)
      {
         // 同一方向禁止
         if(lastDirection == 1)
            breakUp = false;
         
         if(lastDirection == -1)
            breakDown = false;
      }
//***【新規注文判断↑】***//

      //参照するサンプルEAの買いエントリーフラグをセットしてください
      if(breakUp){
         openBuy =true;
         ea_order_Type = OP_BUY;
      //参照するサンプルEAの売りエントリーフラグをセットしてください      
      }else if(breakDown){
         openSell =true;
         ea_order_Type = OP_SELL;
      }

//***【TP/SL判断↓】***//
// TP/SLを変更したい場合はこの部分を変更してください。
// 例：移動平均線のTP/SLを使いたい場合は書き換え
      if(openBuy){
         ea_order_stop_price = Ask - SL * PipValue;
         ea_order_good_price = Ask + TP * PipValue;
      }else if(openSell){
         ea_order_stop_price = Bid + SL * PipValue;  
         ea_order_good_price = Bid - TP * PipValue;   
      }
//***【TP/SL判断↑】***//

      if(ea_order_Type > -1){
         bool ok = funcOrder_Send(ea_order_Type, ea_order_stop_price, ea_order_good_price,Lots, Ea_Name, 777, 0);
         
         if(ok){
            lastDirection = (ea_order_Type == OP_BUY ? 1 : -1);
         }  
      }

   }

   return;
}


//★★★★★★★★★★★★★★★★★★★★ ここから下は共通関数 ★★★★★★★★★★★★★★★★★★★★
//+------------------------------------------------------------------+
//|【関数】新規注文関数
//|
//|【引数】 orderType:売買(0=BUY, 1=SELL)
//|【引数】 sl:損切り価格  tp:利確価格
//|【引数】 lots:取引ロット数
//|【引数】 orderComment:オーダーコメント
//|【引数】 magic:マジックNo
//|【引数】 maxSpreadPips: 許容スプレッド[Point] (0=制限なし)
//|
//|【戻値】true=成功 false=失敗
//+------------------------------------------------------------------+
bool funcOrder_Send(int orderType, double sl, double tp, double lots,
                    string orderComment, int magic, int maxSpreadPoints){
   int    ticket = -1;
   double price  = 0;
   color  clr    = clrNONE;
   double spread = 0;

   // 最大10回リトライ
   for(int retry=0; retry<10; retry++)
   {
      RefreshRates();
      
      // スプレッド取得（MT4表示と同じポイント単位）
      spread = MarketInfo(Symbol(), MODE_SPREAD);

      // スプレッドチェック（maxSpreadPoints=0 の場合はスキップ）
      if(maxSpreadPoints > 0 && spread > maxSpreadPoints){
         Print("スプレッド拡大中(", spread,
               "ポイント) → 待機中 (リトライ=", retry+1, ")");
         Sleep(2000);
         continue;
      }

      // エントリー価格と色を決定
      if(orderType == OP_BUY){
         price = Ask;
         clr   = clrBlue;
      }else if(orderType == OP_SELL){
         price = Bid;
         clr   = clrRed;
      }

      ticket = OrderSend(Symbol(), orderType, lots, price,
                         20, sl, tp, orderComment, magic, 0, clr);

      if(ticket > 0){
         Print("新規注文成功! チケットNo=", ticket,
               " レート=", price, " Lots=", lots,
               " スプレッド=", spread, "ポイント");
         return true;
      }else{
         int err = GetLastError();
         Print("新規注文失敗 エラーNo=", err,
               " リトライ回数=", retry+1);
         Sleep(2000);
      }
   }

   return false;
}