MT4でアリゲーター（Alligator）EAを作成｜無料MQL4サンプルコード解説

▼目次

はじめに
🐊 アリゲーター（Alligator）とは？
1. よくある売買シグナル
EAの概要とポイント
エントリーロジック解説
⚠️ 注意点
ダウンロード
📜 アリゲーターEAのサンプルコード解説
パラメータとカスタマイズ
EAバックテストレポート
まとめ
1. ✅ 他にも多数のEAサンプルを公開中！
2. 📊 【2025年最新】FX自動売買EAランキングも公開中！

はじめに

「アリゲーターを使ったトレンドフォロー型ロジックをEAで自動化したい！」という方向けに、この記事では MT4（MQL4）で動作する無料Alligator EAサンプルコード を紹介します。
初心者でもコピペで動かせるので、学習用や実験用に最適です。

🐊 アリゲーター（Alligator）とは？

アリゲーターはビル・ウィリアムズ氏が開発したテクニカル指標で、3本の平滑移動平均線（SMMA：ジョーズ・ティース・リップス）を使い、相場が「レンジ」か「トレンド」かを見分けます。

3本の平滑移動平均線（SMMA）を使い、市場が「眠っている（レンジ）」なのか「目を覚ました（トレンド）」なのかを判定する指標です。

ジョーズ（青線）：長期の方向を示す
ティース（赤線）：中期の方向を示す
リップス（緑線）：短期の方向を示す

よくある売買シグナル

上昇トレンド（口が上に開く）：リップス > ティース > ジョーズ → 買いサイン
下降トレンド（口が下に開く）：リップス < ティース < ジョーズ → 売りサイン

EAの概要とポイント

MT4標準インジケータの iAlligator() を使用
3本のライン（Jaw・Teeth・Lips）の位置関係と「口の開閉」で売買エントリー
ジョーズ・ティース・リップスの期間やシフト値をパラメータでカスタマイズ可能

エントリーロジック解説

買いエントリー（ロング）

リップス > ティース > ジョーズ（上に開いた状態）
直近のローソク足がリップスより上でクローズ
→ BUY判断

売りエントリー（ショート）

リップス < ティース < ジョーズ（下に開いた状態）
直近のローソク足がリップスより下でクローズ
→ SELL判断

⚠️ 注意点

アリゲーターはトレンド判定に強いですが、レンジ相場ではシグナルが頻発します
RSIやボリンジャーバンドと併用すると精度が向上します
新しいローソク足が確定したタイミングで判定しています
マジックナンバーは考慮していないため、このEA単独で稼働させてください

ダウンロード

EAファイルのダウンロードはこちら👇

📥 アリゲーターEA をダウンロード

📜 アリゲーターEAのサンプルコード解説

以下にMQL4サンプルコードを掲載します。
そのままコピーしてMT4(MetaEditor)に貼り付ければコンパイル可能で、動作確認も済んでいます。

//+------------------------------------------------------------------+
//|                                                 05_Alligator.mq4 |
//|                                Copyright © 2020-2025 ぷろぐらむFX |
//|                                             https://fx-prog.com/ |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2020-2025 ぷろぐらむFX"
#property link      "https://fx-prog.com/"
#property version   "1.00"
#property strict


input double Lots = 0.01;              //ロット
input int TP = 100;                    //利確(pips)
input int SL = 100;                    //損切り(pips)
//***【パラメータ設定↓】アリゲーター***//
input int Jaw_Period   = 13;           // ジョーズ（青線）期間
input int Jaw_Shift    = 8;            // ジョーズ（青線）シフト

input int Teeth_Period = 8;            // ティース（赤線）期間
input int Teeth_Shift  = 5;            // ティース（赤線）シフト

input int Lips_Period  = 5;            // リップス（緑線）期間
input int Lips_Shift   = 3;            // リップス（緑線）シフト
//***【パラメータ設定↑】アリゲーター***//

string Ea_Name = "Alligator";          //オーダーコメントに使用

double PipValue;                       //ブローカー桁数に対応した Point 補正
datetime prevtime;                     //ローソク足時間保持用
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit(){

   //デジットチェック
   if (Digits == 3 || Digits == 5){
      PipValue = Point * 10;   // 例: EURUSD 1.23456 → 1pip = 0.00010
   }else{
      PipValue = Point;        // 例: USDJPY 123.45 → 1pip = 0.01
   }

   return(INIT_SUCCEEDED);
}
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason){

}
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick(){

   int total = OrdersTotal();    //ポジショントータル数をセット  
   int ea_order_Type = -1; //0:OP_BUY  1:OP_SELL
   double ea_order_stop_price = 0; //ストップロスレート
   double ea_order_good_price = 0; //利確レート

   //新しい足ができた時だけやる
   if(Time[0] != prevtime){
      prevtime = Time[0];
   }else{
      return;
   }

   //ポジションがない場合はエントリー判定
   if(total == 0){

      bool openBuy  = false;    //買い新規注文判断
      bool openSell = false;    //売り新規注文判断
      
//***【新規注文判断↓】***//

      bool isBullAlligator_S = false;
      bool isBearAlligator_S = false;

      //ジョーズライン
      double JAW_ATAI_1 = iAlligator(NULL, 0, Jaw_Period, Jaw_Shift, Teeth_Period, Teeth_Shift, Lips_Period ,Lips_Shift, MODE_SMMA, PRICE_MEDIAN, MODE_GATORJAW, 1);
      double JAW_ATAI_2 = iAlligator(NULL, 0, Jaw_Period, Jaw_Shift, Teeth_Period, Teeth_Shift, Lips_Period ,Lips_Shift, MODE_SMMA, PRICE_MEDIAN, MODE_GATORJAW, 2);
      
      //ティースライン
      double TEETH_ATAI_1 = iAlligator(NULL, 0, Jaw_Period, Jaw_Shift, Teeth_Period, Teeth_Shift, Lips_Period ,Lips_Shift, MODE_SMMA, PRICE_MEDIAN, MODE_GATORTEETH, 1);
      double TEETH_ATAI_2 = iAlligator(NULL, 0, Jaw_Period, Jaw_Shift, Teeth_Period, Teeth_Shift, Lips_Period ,Lips_Shift, MODE_SMMA, PRICE_MEDIAN, MODE_GATORTEETH, 2);
      
      //リップスライン
      double LIPS_ATAI_1 = iAlligator(NULL, 0, Jaw_Period, Jaw_Shift, Teeth_Period, Teeth_Shift, Lips_Period ,Lips_Shift, MODE_SMMA, PRICE_MEDIAN, MODE_GATORLIPS, 1);
      double LIPS_ATAI_2 = iAlligator(NULL, 0, Jaw_Period, Jaw_Shift, Teeth_Period, Teeth_Shift, Lips_Period ,Lips_Shift, MODE_SMMA, PRICE_MEDIAN, MODE_GATORLIPS, 2);
      
      //ローソク足の1つ前のクローズ値情報を取得しておく
      double rosokuValueCloseP_Alli = iClose(NULL, 0, 1);
   
      //=== 開き具合の計算 ===//
      double lipsTeethDiff = MathAbs(LIPS_ATAI_1 - TEETH_ATAI_1);
      double teethJawDiff  = MathAbs(TEETH_ATAI_1 - JAW_ATAI_1);
      bool isOpenedUp = (LIPS_ATAI_1 > TEETH_ATAI_1 && TEETH_ATAI_1 > JAW_ATAI_1);
      
      //=== 上昇トレンドで落ち着いた状態 ===//
      if(isOpenedUp && lipsTeethDiff > Point*10 && teethJawDiff > Point*10 
         && rosokuValueCloseP_Alli > LIPS_ATAI_1)
      {
         isBullAlligator_S = true;
      }
      
      //=== 下降トレンドで落ち着いた状態 ===//
      bool isOpenedDown = (LIPS_ATAI_1 < TEETH_ATAI_1 && TEETH_ATAI_1 < JAW_ATAI_1);
      if(isOpenedDown && lipsTeethDiff > Point*10 && teethJawDiff > Point*10 
         && rosokuValueCloseP_Alli < LIPS_ATAI_1)
      {
         isBearAlligator_S = true;
      }

//***【新規注文判断↑】***//

      //参照するサンプルEAの買いエントリーフラグをセットしてください
      if(isBullAlligator_S){
         openBuy =true;
         ea_order_Type = OP_BUY;
      //参照するサンプルEAの売りエントリーフラグをセットしてください      
      }else if(isBearAlligator_S){
         openSell =true;
         ea_order_Type = OP_SELL;
      }

//***【TP/SL判断↓】***//
      if(openBuy){
         ea_order_stop_price = Ask - SL * PipValue;
         ea_order_good_price = Ask + TP * PipValue;
      }else if(openSell){
         ea_order_stop_price = Bid + SL * PipValue;  
         ea_order_good_price = Bid - TP * PipValue;   
      }
//***【TP/SL判断↑】***//

      if(ea_order_Type > -1){
         funcOrder_Send(ea_order_Type,ea_order_stop_price,ea_order_good_price,Lots,Ea_Name,777,0);
      }
      
   //ポジションがある場合は決済判定   
   }else{
   
      bool closeBuy  = false;    //買いポジション決済判断
      bool closeSell = false;    //売りポジション決済判断
      bool kekka = OrderSelect(0,SELECT_BY_POS,MODE_TRADES);      //ポジション確認

//***【決済注文判断↓】***//

      bool isBullAlligator_C = false;
      bool isBearAlligator_C = false;

      //ジョーズライン
      double JAW_ATAI_1 = iAlligator(NULL, 0, Jaw_Period, Jaw_Shift, Teeth_Period, Teeth_Shift, Lips_Period ,Lips_Shift, MODE_SMMA, PRICE_MEDIAN, MODE_GATORJAW, 1);
      double JAW_ATAI_2 = iAlligator(NULL, 0, Jaw_Period, Jaw_Shift, Teeth_Period, Teeth_Shift, Lips_Period ,Lips_Shift, MODE_SMMA, PRICE_MEDIAN, MODE_GATORJAW, 2);
      
      //ティースライン
      double TEETH_ATAI_1 = iAlligator(NULL, 0, Jaw_Period, Jaw_Shift, Teeth_Period, Teeth_Shift, Lips_Period ,Lips_Shift, MODE_SMMA, PRICE_MEDIAN, MODE_GATORTEETH, 1);
      double TEETH_ATAI_2 = iAlligator(NULL, 0, Jaw_Period, Jaw_Shift, Teeth_Period, Teeth_Shift, Lips_Period ,Lips_Shift, MODE_SMMA, PRICE_MEDIAN, MODE_GATORTEETH, 2);
      
      //リップスライン
      double LIPS_ATAI_1 = iAlligator(NULL, 0, Jaw_Period, Jaw_Shift, Teeth_Period, Teeth_Shift, Lips_Period ,Lips_Shift, MODE_SMMA, PRICE_MEDIAN, MODE_GATORLIPS, 1);
      double LIPS_ATAI_2 = iAlligator(NULL, 0, Jaw_Period, Jaw_Shift, Teeth_Period, Teeth_Shift, Lips_Period ,Lips_Shift, MODE_SMMA, PRICE_MEDIAN, MODE_GATORLIPS, 2);
      
      //ローソク足の1つ前のクローズ値情報を取得しておく
      double rosokuValueCloseP_Alli = iClose(NULL, 0, 1);
      
      //=== 開き具合の計算 ===//
      double lipsTeethDiff = MathAbs(LIPS_ATAI_1 - TEETH_ATAI_1);
      double teethJawDiff  = MathAbs(TEETH_ATAI_1 - JAW_ATAI_1);
      bool isOpenedUp = (LIPS_ATAI_1 > TEETH_ATAI_1 && TEETH_ATAI_1 > JAW_ATAI_1);
      
      // ポジションがBUYの場合
      if(OrderType() == OP_BUY){
         if(LIPS_ATAI_1 < TEETH_ATAI_1 || lipsTeethDiff < Point*5 || teethJawDiff < Point*5){
            isBullAlligator_C = true;  // 決済条件
         }
      }
      // ポジションがSELLの場合      
      else if(OrderType() == OP_SELL){
         if(LIPS_ATAI_1 > TEETH_ATAI_1 || lipsTeethDiff < Point*5 || teethJawDiff < Point*5){
            isBearAlligator_C = true;  // 決済条件
         }
      }

//***【決済注文判断↑】***//
   
      //参照するサンプルEAの買いポジション決済フラグをセットしてください
      if(isBullAlligator_C){
         closeBuy =true;
         ea_order_Type = OP_BUY;
      //参照するサンプルEAの売りポジション決済フラグをセットしてください
      }else if(isBearAlligator_C){
         closeSell =true;
         ea_order_Type = OP_SELL;
      }
      
      if(ea_order_Type > -1){
         funcOrder_CloseAll(ea_order_Type, -1, 0);
      }
      
   }

   return;
}


//★★★★★★★★★★★★★★★★★★★★ ここから下は共通関数 ★★★★★★★★★★★★★★★★★★★★
//+------------------------------------------------------------------+
//|【関数】新規注文関数
//|
//|【引数】 orderType:売買(0=BUY, 1=SELL)
//|【引数】 sl:損切り価格  tp:利確価格
//|【引数】 lots:取引ロット数
//|【引数】 orderComment:オーダーコメント
//|【引数】 magic:マジックNo
//|【引数】 maxSpreadPips: 許容スプレッド[Point] (0=制限なし)
//|
//|【戻値】true=成功 false=失敗
//+------------------------------------------------------------------+
bool funcOrder_Send(int orderType, double sl, double tp, double lots,
                    string orderComment, int magic, int maxSpreadPoints){
   int    ticket = -1;
   double price  = 0;
   color  clr    = clrNONE;
   double spread = 0;

   // 最大10回リトライ
   for(int retry=0; retry<10; retry++)
   {
      RefreshRates();
      
      // スプレッド取得（MT4表示と同じポイント単位）
      spread = MarketInfo(Symbol(), MODE_SPREAD);

      // スプレッドチェック（maxSpreadPoints=0 の場合はスキップ）
      if(maxSpreadPoints > 0 && spread > maxSpreadPoints){
         Print("スプレッド拡大中(", spread,
               "ポイント) → 待機中 (リトライ=", retry+1, ")");
         Sleep(2000);
         continue;
      }

      // エントリー価格と色を決定
      if(orderType == OP_BUY){
         price = Ask;
         clr   = clrBlue;
      }else if(orderType == OP_SELL){
         price = Bid;
         clr   = clrRed;
      }

      ticket = OrderSend(Symbol(), orderType, lots, price,
                         20, sl, tp, orderComment, magic, 0, clr);

      if(ticket > 0){
         Print("新規注文成功! チケットNo=", ticket,
               " レート=", price, " Lots=", lots,
               " スプレッド=", spread, "ポイント");
         return true;
      }else{
         int err = GetLastError();
         Print("新規注文失敗 エラーNo=", err,
               " リトライ回数=", retry+1);
         Sleep(2000);
      }
   }

   return false;
}
 
    
//+------------------------------------------------------------------+
//|【関数】全決済関数                                                 |
//|                                                                  |
//|【引数】 orderType : -1=すべて  0=BUYのみ  1=SELLのみ             |
//|【引数】 magic: 対象マジック番号 (-1=全マジック対象)               |
//|【引数】 maxSpreadPoints: 許容スプレッド[Point] (0=制限なし)       |
//|                                                                  |
//|【戻値】true=全成功 false=一部失敗あり                             |
//+------------------------------------------------------------------+
bool funcOrder_CloseAll(int orderType, int magic, int maxSpreadPoints){
   bool allSuccess = true;
   int totalOrders = OrdersTotal();
   double spread, closePrice, lots;
   int type, ticket;
   color  clr    = clrNONE;

   for(int i = totalOrders-1; i >= 0; i--)
   {
      //オーダーセレクト失敗でスキップ
      if(!OrderSelect(i, SELECT_BY_POS, MODE_TRADES)) continue;
      
      // 同一シンボル以外はスキップ
      if(OrderSymbol() != Symbol()) continue;

      // マジック番号指定がある場合は一致しないものをスキップ
      if(magic != -1 && OrderMagicNumber() != magic) continue;

      type   = OrderType();
      ticket = OrderTicket();
      lots   = OrderLots();

      // orderType指定でフィルタ
      if(orderType == 0 && type != OP_BUY) continue;
      if(orderType == 1 && type != OP_SELL) continue;

      // 最大10回リトライ
      bool result = false;
      for(int retry=0; retry<10; retry++)
      {
         RefreshRates();

         // スプレッド取得
         spread = MarketInfo(Symbol(), MODE_SPREAD);

         if(maxSpreadPoints > 0 && spread > maxSpreadPoints){
            Print("スプレッド拡大中(", spread,
                  "ポイント) → クローズ待機中 ticket=", ticket,
                  " リトライ=", retry+1);
            Sleep(2000);
            continue;
         }

         // クローズ価格決定
         if(type == OP_BUY){
            closePrice = Bid;
            clr   = clrBlue;
         }else if(type == OP_SELL){
            closePrice = Ask;
            clr   = clrRed;
         }

         result = OrderClose(ticket, lots, closePrice, 20, clr);

         if(result){
            Print("クローズ成功! チケットNo=", ticket,
                  " ロット=", lots, " クローズ価格=", closePrice,
                  " スプレッド=", spread, "ポイント");
            break;
         }else{
            int err = GetLastError();
            Print("クローズ失敗 ticket=", ticket,
                  " エラーNo=", err,
                  " リトライ=", retry+1);
            Sleep(2000);
         }
      }

      if(!result) allSuccess = false;
   }

   return allSuccess;
}

iAlligator() 関数の解説

短期・中期・長期ラインの値を取得するために、MT4標準関数 iAlligator() を使用します。

【使用例】

double jaw   = iAlligator(NULL, 0, 13, 8, 8, 5, 5, 3, MODE_SMMA, PRICE_MEDIAN, MODE_GATORJAW, 1);
double teeth = iAlligator(NULL, 0, 13, 8, 8, 5, 5, 3, MODE_SMMA, PRICE_MEDIAN, MODE_GATORTEETH, 1);
double lips  = iAlligator(NULL, 0, 13, 8, 8, 5, 5, 3, MODE_SMMA, PRICE_MEDIAN, MODE_GATORLIPS, 1);

引数の意味

引数1 … 通貨ペア
NULL で現在のチャートを対象
引数2 … 時間軸
0 で現在の時間足を対象
引数3 … ジョーズ（青線）期間
アリゲーターの設定。パラメータ設定で変更可能
引数4 … ジョーズ（青線）シフト
右にずらすバー数。パラメータ設定で変更可能
引数5 … ティース（赤線）期間
アリゲーターの設定。パラメータ設定で変更可能
引数6 … ティース（赤線）シフト
右にずらすバー数。パラメータ設定で変更可能
引数7 … リップス（緑線）期間
アリゲーターの設定。パラメータ設定で変更可能
引数8 … リップス（緑線）シフト
右にずらすバー数。パラメータ設定で変更可能
引数9 … 移動平均の手法（MA手法）
MODE_SMA / MODE_EMA / MODE_SMMA / MODE_LWMA から選択
（アリゲーターは通常 MODE_SMMA）
引数10 … 価格適用方法
PRICE_CLOSE / PRICE_MEDIAN などから選択
（アリゲーターは通常 PRICE_MEDIAN）
引数11 … 取得モード
どの線の値を取得するか指定
MODE_GATORJAW → ジョーズ（青線）
MODE_GATORTEETH → ティース（赤線）
MODE_GATORLIPS → リップス（緑線）
引数12 … バーシフト
0 = 最新足、1 = 1本前、2 = 2本前の値を取得

アリゲーター利用箇所

新規注文処理（73～111行目）
→ リップス・ティース・ジョーズの順序をチェックして売買方向を決定
決済処理（146～182行目）
→ リップスがティースを上抜け、下抜け、もしくは 3本の距離が縮小してきたら決済

アリゲーターを使った売買判定について

エントリー条件
- ロング：リップス > ティース > ジョーズ
- ショート：リップス < ティース < ジョーズ
補強ロジック
- ライン間隔が広がる（口が開く）ほどトレンドが強いと判定
利確・損切設定
決済処理で決済させたいため、どちらも1000pipsに初期設定しています
※パラメータ設定で自由に変更してください

新規注文・決済注文関数

本記事のアリゲーターEAで使用している「新規注文、決済注文処理」は、当サイト共通のベースソースに含まれています。
EAを効率的に自作したい方は、以下も参考にしてください👇

👉 MT4 EAベースソースコード（無料配布・カスタマイズ容易）
👉 新規・変更・決済注文関数の詳しい解説はこちら

パラメータとカスタマイズ

今回のパラメータ設定は以下の通りです：

取引ロット数（例：0.01 = 1,000通貨）
利確幅（pips）
損切幅（pips）
ジョーズ(青線)期間、シフト：13、8
ティース(赤線)期間、シフト：8、5
リップス(緑線)期間、シフト：5、3

EAバックテストレポート

USDJPY（M15, 2024/08〜2025/08, 初期証拠金100万円, FXTFヒストリカル）での結果：

通貨ペア・時間足	PF	勝率	最大DD	取引回数	備考
USDJPY M15	1.44	42%	0.35%	291回	大きく負け越すことも無く堅実に勝てている

まとめ

アリゲーターEAは「トレンド相場で強さを発揮」する順張りロジックです。

シンプルなトレンドフォロー戦略で初心者にも分かりやすい
レンジではだましシグナルが多いため、RSIやボリバン併用がおすすめ
パラメータを調整することで通貨ペアや時間足に最適化可能

まずはサンプルコードを試してみて、自分の環境でバックテストを行いましょう。
フィルタ追加やロジック改良次第で、実用的なEAへ進化させられます。

🛠️ EAを効率的にカスタマイズしたい方へ
▶ 【MT4 EAベースソース】を無料公開中！初心者でもすぐに使えます。

✅ 他にも多数のEAサンプルを公開中！

今回紹介した内容以外にも、当サイトではさまざまな
FX自動売買EAのサンプルコードを提供しています。

自分に合った戦略のEAを見つけたい方は、ぜひチェックしてみてください。

📊 【2025年最新】FX自動売買EAランキングも公開中！

当サイトの「どのEA(インジ)が実際に勝っているのか？」を知りたい方はこちら👇
PF（プロフィットファクター）や勝率で徹底比較した最新ランキングから、あなたに最適なEA(インジ)を見つけましょう。

EA開発初心者向けに、今後も実践的なMQL4関数を紹介していきます。
気になる機能やロジックがあれば、ぜひ他の記事もあわせてご覧ください！

久保健一より:
2021年6月6日 10:07 PM
初めましてm(__)m　　久保と申しますm(__)m　いつも凄いプログラムの能力が無茶苦茶凄いな～と感心して読ませて頂いております。突然ですが、このアリゲーターEAを15分足設定にしたいのですがどうしたら設定できますか？
お忙しい中申し訳ありませんがご回答をお待ちしておりますm(__)m
返信
- りょうより:
  2021年6月7日 8:36 AM
  初めまして、久保さん。ブログを見て頂いて有難うございます！15分足で動かしたい場合、15分足のチャートを表示してそこにEAを読み込ませると15分足で動くと思いますがそういった話ではないですか？サンプルEAは基本的にオススメの推奨時間（分）足はありますが、どの足でも動きます！
  返信
さかより:
2022年9月6日 10:23 PM
はじめまして、こちらのサンプルコードで動かしてみましたが、ポジション持ちません、コンパイルが間違えているのかそれともMT4の愛称なのかわかりませんが、動かす方法ありませんか、
返信
- りょうより:
  2022年9月6日 11:10 PM
  さかさんはじめまして。
  ファイルができているのであれば、コンパイルは成功しています。バックテストでポジションを持たない感じでしょうか？こちらはデフォルト10より小さい場合しか動かないので小さいスプレッドで試して頂くとどうでしょうか？
  返信