MT4 平均足とは？設定方法・使い方とEA化サンプルを解説

//+------------------------------------------------------------------+
//|                                                04_HeikinAshi.mq4 |
//|                                Copyright © 2020-2026 ぷろぐらむFX |
//|                                             https://fx-prog.com/ |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2020-2026 ぷろぐらむFX"
#property link      "https://fx-prog.com/"
#property version   "1.00"
#property strict

input double Lots = 0.01;              //ロット
input int TP = 1000;                   //利確(pips)
input int SL = 1000;                   //損切り(pips)

string Ea_Name = WindowExpertName();   //EA名称をオーダーコメントに使用
double PipValue;                       //ブローカー桁数に対応したPoint補正
datetime prevtime;                     //ローソク足時間保持用

int OnInit(){
   if(Digits == 3 || Digits == 5){
      PipValue = Point * 10;
   }else{
      PipValue = Point;
   }
   return(INIT_SUCCEEDED);
}

void OnTick(){
   if(Time[0] != prevtime){
      prevtime = Time[0];
   }else{
      return;
   }

   int total = OrdersTotal();
   int ea_order_Type = -1;
   double ea_order_stop_price = 0;
   double ea_order_good_price = 0;

   bool openBuy = false;
   bool openSell = false;

//***【新規注文判断↓】***//
   double haOpen1 = iCustom(NULL,0,"Heiken Ashi",2,1);
   double haClose1 = iCustom(NULL,0,"Heiken Ashi",3,1);
   double haOpen2 = iCustom(NULL,0,"Heiken Ashi",2,2);
   double haClose2 = iCustom(NULL,0,"Heiken Ashi",3,2);

   if(haClose2 < haOpen2 && haClose1 > haOpen1){
      openBuy = true;
   }else if(haClose2 > haOpen2 && haClose1 < haOpen1){
      openSell = true;
   }
//***【新規注文判断↑】***//

//***【決済注文判断↓】***//
   if(total > 0){
      if(openBuy){
         if(!funcOrder_CloseAll(OP_SELL,-1,0)) return;
      }else if(openSell){
         if(!funcOrder_CloseAll(OP_BUY,-1,0)) return;
      }
   }
//***【決済注文判断↑】***//

   if(OrdersTotal() == 0){
      if(openBuy){
         ea_order_Type = OP_BUY;
      }else if(openSell){
         ea_order_Type = OP_SELL;
      }

//***【TP/SL判断↓】***//
      if(openBuy){
         ea_order_stop_price = Ask - SL * PipValue;
         ea_order_good_price = Ask + TP * PipValue;
      }else if(openSell){
         ea_order_stop_price = Bid + SL * PipValue;
         ea_order_good_price = Bid - TP * PipValue;
      }
//***【TP/SL判断↑】***//

      if(ea_order_Type > -1){
         funcOrder_Send(ea_order_Type,ea_order_stop_price,ea_order_good_price,Lots,Ea_Name,0,0);
      }
   }
}


//★★★★★★★★★★★★★★★★★★★★ ここから下は共通関数 ★★★★★★★★★★★★★★★★★★★★

//+------------------------------------------------------------------+
//|【関数】新規注文関数                                              |
//|【引数】orderType:売買(0=BUY, 1=SELL)                            |
//|【引数】sl:損切り価格  tp:利確価格                               |
//|【引数】lots:取引ロット数                                         |
//|【引数】orderComment:オーダーコメント                             |
//|【引数】magic:MagicNumber                                         |
//|【引数】maxSpreadPoints:許容スプレッド[Point] (0=制限なし)       |
//|【戻値】true=成功 false=失敗                                      |
//+------------------------------------------------------------------+
bool funcOrder_Send(int orderType, double sl, double tp, double lots, string orderComment, int magic, int maxSpreadPoints){

   int ticket = -1;
   double price = 0;
   double spread = 0;
   color clr = clrNONE;

   for(int retry=0; retry<10; retry++){

      RefreshRates();
      spread = MarketInfo(Symbol(),MODE_SPREAD);

      if(maxSpreadPoints > 0 && spread > maxSpreadPoints){
         Print("スプレッド拡大中(",spread,"ポイント) → 待機中 (リトライ=",retry+1,")");
         Sleep(2000);
         continue;
      }

      if(orderType == OP_BUY){
         price = Ask;
         clr = clrBlue;
      }else if(orderType == OP_SELL){
         price = Bid;
         clr = clrRed;
      }else{
         Print("funcOrder_Send: 未対応の注文種別=",orderType);
         return false;
      }

      price = NormalizeDouble(price,Digits);

      if(sl > 0) sl = NormalizeDouble(sl,Digits);
      if(tp > 0) tp = NormalizeDouble(tp,Digits);

      ResetLastError();

      ticket = OrderSend(Symbol(),orderType,lots,price,20,sl,tp,orderComment,magic,0,clr);

      if(ticket > 0){
         Print("新規注文成功! チケットNo=",ticket," レート=",price," Lots=",lots," スプレッド=",spread,"ポイント");
         return true;
      }

      int err = GetLastError();
      Print("新規注文失敗 エラーNo=",err," リトライ回数=",retry+1);
      Sleep(2000);
   }

   return false;
}

//+------------------------------------------------------------------+
//|【関数】全決済関数                                                |
//|【引数】orderType:-1=すべて 0=BUYのみ 1=SELLのみ                 |
//|【引数】magic:対象MagicNumber (-1=全MagicNumber)                  |
//|【引数】maxSpreadPoints:許容スプレッド[Point] (0=制限なし)       |
//|【戻値】true=全成功 false=一部失敗あり                           |
//+------------------------------------------------------------------+
bool funcOrder_CloseAll(int orderType, int magic, int maxSpreadPoints){

   bool allSuccess = true;
   int totalOrders = OrdersTotal();
   double spread = 0;
   double closePrice = 0;
   double lots = 0;
   int type = -1;
   int ticket = -1;
   color clr = clrNONE;

   for(int i=totalOrders-1; i>=0; i--){

      if(!OrderSelect(i,SELECT_BY_POS,MODE_TRADES)) continue;
      if(OrderSymbol() != Symbol()) continue;
      if(magic != -1 && OrderMagicNumber() != magic) continue;

      type = OrderType();
      ticket = OrderTicket();
      lots = OrderLots();

      if(type != OP_BUY && type != OP_SELL) continue;
      if(orderType == OP_BUY && type != OP_BUY) continue;
      if(orderType == OP_SELL && type != OP_SELL) continue;

      bool result = false;

      for(int retry=0; retry<10; retry++){

         RefreshRates();
         spread = MarketInfo(Symbol(),MODE_SPREAD);

         if(maxSpreadPoints > 0 && spread > maxSpreadPoints){
            Print("スプレッド拡大中(",spread,"ポイント) → クローズ待機中 ticket=",ticket," リトライ=",retry+1);
            Sleep(2000);
            continue;
         }

         if(type == OP_BUY){
            closePrice = Bid;
            clr = clrBlue;
         }else{
            closePrice = Ask;
            clr = clrRed;
         }

         closePrice = NormalizeDouble(closePrice,Digits);
         ResetLastError();

         result = OrderClose(ticket,lots,closePrice,20,clr);

         if(result){
            Print("クローズ成功! チケットNo=",ticket," ロット=",lots," クローズ価格=",closePrice," スプレッド=",spread,"ポイント");
            break;
         }

         int err = GetLastError();
         Print("クローズ失敗 ticket=",ticket," エラーNo=",err," リトライ=",retry+1);
         Sleep(2000);
      }

      if(!result) allSuccess = false;
   }

   return allSuccess;
}