MT4｜ポジションのpips数を計算する汎用関数【MQL4サンプルコード付き】

//+------------------------------------------------------------------+
//| 【関数】指定ポジション種別のpipsを返す                          |
//|                                                                  |
//| 【引数】type：0=BUY, 1=SELL                                      |
//| 【引数】mode：0=総数, 1=最新1ポジのみ                            |
//| 【引数】magic：EAのマジックナンバー（-1ならすべて対象）          |
//|                                                                  |
//| 【戻値】指定ポジションの合計pips（mode=1のときは最新1ポジ分）   |
//+------------------------------------------------------------------+
double getTotalProfitPips(int type, int mode, int magic)
{
   double totalPips = 0.0;

   for(int i = OrdersTotal() - 1; i >= 0; i--)
   {
      if(!OrderSelect(i, SELECT_BY_POS, MODE_TRADES)) continue;

      // 通貨ペア・注文種別・マジックナンバーでフィルタ
      if(OrderSymbol() != Symbol())                    continue;
      if(OrderType() != OP_BUY && OrderType() != OP_SELL) continue;
      if(type == 0 && OrderType() != OP_BUY)           continue;
      if(type == 1 && OrderType() != OP_SELL)          continue;
      if(magic != -1 && OrderMagicNumber() != magic)   continue;

      double pips = 0.0;

      // BUY／SELLでpipsの向きを計算
      if(OrderType() == OP_BUY)
      {
         pips = Bid - OrderOpenPrice();
      }
      else if(OrderType() == OP_SELL)
      {
         pips = OrderOpenPrice() - Ask;
      }

      // 通貨の桁数に応じたpips換算
      if(Symbol() == "GOLD")
      {
         // 口座仕様によって調整（例：XMのGOLDなど）
         pips *= 10;
      }
      else
      {
         if(Digits == 2 || Digits == 3)
         {
            pips *= 100;
         }
         else if(Digits == 4 || Digits == 5)
         {
            pips *= 10000;
         }
      }

      totalPips += pips;

      // 単ポジモードの場合は1回で抜ける
      if(mode == 1)
      {
         break;
      }
   }

   return totalPips;
}

double B_pips = getTotalProfitPips(0, 0, MAGIC_NO);  // BUYポジションの総pips数を取得
double S_pips = getTotalProfitPips(1, 1, MAGIC_NO);  // SELLポジションの最新1ポジpips数を取得

int total = OrdersTotal();

if(total > 0)
{
   // 単ポジの場合は +20pips で決済する
   if(total == 1)
   {
      if(getTotalProfitPips(e_type, 1, MAGIC_NO) >= 20)
      {
         // 単ポジ決済処理
      }
   }
   // 複数ポジの場合はトータル +10pips で決済する
   else
   {
      if(getTotalProfitPips(e_type, 0, MAGIC_NO) >= 10)
      {
         // e_type のポジション全決済処理
      }
   }
}