MT4で平均足EAを作成｜無料MQL4サンプルコード解説

//+------------------------------------------------------------------+
//|                                                04_HeikinAshi.mq4 |
//|                                Copyright © 2020-2025 ぷろぐらむFX |
//|                                             https://fx-prog.com/ |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2020-2025 ぷろぐらむFX"
#property link      "https://fx-prog.com/"
#property version   "1.00"
#property strict


input double Lots = 0.01;              //ロット
input int TP = 1000;                   //利確(pips)
input int SL = 1000;                   //損切り(pips)
//***【パラメータ設定↓】平均足***//
input double HEIKIN_SIKII = 0.5;       //ヒゲ比率しきい値
//***【パラメータ設定↑】平均足***//

string Ea_Name = "HeikinAshi";         //オーダーコメントに使用

double PipValue;                       //ブローカー桁数に対応した Point 補正
datetime prevtime;                     //ローソク足時間保持用
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit(){

   //デジットチェック
   if (Digits == 3 || Digits == 5){
      PipValue = Point * 10;   // 例: EURUSD 1.23456 → 1pip = 0.00010
   }else{
      PipValue = Point;        // 例: USDJPY 123.45 → 1pip = 0.01
   }

   return(INIT_SUCCEEDED);
}
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason){

}
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick(){

   int total = OrdersTotal();    //ポジショントータル数をセット  
   int ea_order_Type = -1; //0:OP_BUY  1:OP_SELL
   double ea_order_stop_price = 0; //ストップロスレート
   double ea_order_good_price = 0; //利確レート

   //新しい足ができた時だけやる
   if(Time[0] != prevtime){
      prevtime = Time[0];
   }else{
      return;
   }

   //ポジションがない場合はエントリー判定
   if(total == 0){

      bool openBuy  = false;    //買い新規注文判断
      bool openSell = false;    //売り新規注文判断
      
//***【新規注文判断↓】***//
   //=== 平均足シグナル判定===//
   bool isBullHeikinAshi_S = false;
   bool isBearHeikinAshi_S = false;
   
   //=== 直近2本の平均足取得 ===//
   double haOpen1  = iCustom(NULL, 0, "Heiken Ashi", 2, 1);
   double haClose1 = iCustom(NULL, 0, "Heiken Ashi", 3, 1);
   double haOpen2  = iCustom(NULL, 0, "Heiken Ashi", 2, 2);
   double haClose2 = iCustom(NULL, 0, "Heiken Ashi", 3, 2);
   
   double haDiff1 = haClose1 - haOpen1; //1本前の実体
   double haDiff2 = haClose2 - haOpen2; //2本前の実体
   
   // ヒゲの長さ（上下ヒゲの合計）
   double haHigh1 = iHigh(NULL, 0, 1);
   double haLow1  = iLow(NULL, 0, 1);
   double body1   = haDiff1;
   double wick1   = (haHigh1 - haLow1) - MathAbs(body1);
   
   // 日足の方向判定
   double dayOpen  = iCustom(NULL, PERIOD_D1, "Heiken Ashi", 2, 0);
   double dayClose = iCustom(NULL, PERIOD_D1, "Heiken Ashi", 3, 0);
   double dayDiff  = dayClose - dayOpen;
   
   // 実体とヒゲの比率しきい値
   double ratio = HEIKIN_SIKII; // 実体がヒゲの0倍以上なら強い足と判断
   
   //=== シグナル判定 ===//
   // 直近2本で陰→陽の転換、かつ日足も陽なら買い
   if(haDiff2 < 0 && haDiff1 > 0 && dayDiff > 0)
   {
       if(MathAbs(body1) > wick1 * ratio) // ヒゲが長すぎない＝強い足
           isBullHeikinAshi_S = true;
   }
   
   // 直近2本で陽→陰の転換、かつ日足も陰なら売り
   else if(haDiff2 > 0 && haDiff1 < 0 && dayDiff < 0)
   {
       if(MathAbs(body1) > wick1 * ratio) // ヒゲが長すぎない＝強い足
           isBearHeikinAshi_S = true;
   }
   
   //=== 直近損切り抑制（任意） ===//
   if(OrdersHistoryTotal() > 0)
   {
       if(OrderSelect(OrdersHistoryTotal()-1, SELECT_BY_POS, MODE_HISTORY))
       {
           datetime recentTime = iTime(NULL, 0, 3); // 直近3本以内
           bool isRecent = OrderCloseTime() > recentTime;
           bool sameDirectionLoss = isRecent &&
                                    (OrderProfit() < 0) &&
                                    ((OrderType() == OP_BUY && isBullHeikinAshi_S) ||
                                     (OrderType() == OP_SELL && isBearHeikinAshi_S));
           if(sameDirectionLoss)
           {
               isBullHeikinAshi_S = false;
               isBearHeikinAshi_S = false;
           }
       }
   }

   
//***【新規注文判断↑】***//

      //参照するサンプルEAの買いエントリーフラグをセットしてください
      if(isBullHeikinAshi_S){
         openBuy =true;
         ea_order_Type = OP_BUY;
      //参照するサンプルEAの売りエントリーフラグをセットしてください      
      }else if(isBearHeikinAshi_S){
         openSell =true;
         ea_order_Type = OP_SELL;
      }

//***【TP/SL判断↓】***//
      if(openBuy){
         ea_order_stop_price = Ask - SL * PipValue;
         ea_order_good_price = Ask + TP * PipValue;
      }else if(openSell){
         ea_order_stop_price = Bid + SL * PipValue;  
         ea_order_good_price = Bid - TP * PipValue;   
      }
//***【TP/SL判断↑】***//

      if(ea_order_Type > -1){
         funcOrder_Send(ea_order_Type,ea_order_stop_price,ea_order_good_price,Lots,Ea_Name,777,0);
      }
      
   //ポジションがある場合は決済判定   
   }else{
   
      bool closeBuy  = false;    //買いポジション決済判断
      bool closeSell = false;    //売りポジション決済判断
      
//***【決済注文判断↓】***//
      bool isBullHeikinAshi_C = false;
      bool isBearHeikinAshi_C = false;
   
       //***平均足の確認***//
      double haOpen1 = iCustom(NULL,0,"Heiken Ashi",2,1);//１つ前の足の平均足始値
      double haClose1 = iCustom(NULL,0,"Heiken Ashi",3,1);//１つ前の足の平均足終値
           
      double haOpen2 = iCustom(NULL,0,"Heiken Ashi",2,2);//２つ前の足の平均足始値
      double haClose2 = iCustom(NULL,0,"Heiken Ashi",3,2);//２つ前の足の平均足終値
           
      double HaDifference1 = haClose1 - haOpen1;//マイナスなら赤色、プラスなら白色
      double HaDifference2 = haClose2 - haOpen2;//マイナスなら赤色、プラスなら白色
      
      if(HaDifference1<0 && OrderType() == OP_BUY){
         isBullHeikinAshi_C = true;
      }
       
      if(HaDifference1>0 &&  OrderType() == OP_SELL){
         isBearHeikinAshi_C = true;
      }   
   
//***【決済注文判断↑】***//
   
      //参照するサンプルEAの買いポジション決済フラグをセットしてください
      if(isBullHeikinAshi_C){
         closeBuy =true;
         ea_order_Type = OP_BUY;
      //参照するサンプルEAの売りポジション決済フラグをセットしてください
      }else if(isBearHeikinAshi_C){
         closeSell =true;
         ea_order_Type = OP_SELL;
      }
      
      if(ea_order_Type > -1){
         funcOrder_CloseAll(ea_order_Type, -1, 0);
      }
      
   }

   return;
}


//★★★★★★★★★★★★★★★★★★★★ ここから下は共通関数 ★★★★★★★★★★★★★★★★★★★★
//+------------------------------------------------------------------+
//|【関数】新規注文関数
//|
//|【引数】 orderType:売買(0=BUY, 1=SELL)
//|【引数】 sl:損切り価格  tp:利確価格
//|【引数】 lots:取引ロット数
//|【引数】 orderComment:オーダーコメント
//|【引数】 magic:マジックNo
//|【引数】 maxSpreadPips: 許容スプレッド[Point] (0=制限なし)
//|
//|【戻値】true=成功 false=失敗
//+------------------------------------------------------------------+
bool funcOrder_Send(int orderType, double sl, double tp, double lots,
                    string orderComment, int magic, int maxSpreadPoints){
   int    ticket = -1;
   double price  = 0;
   color  clr    = clrNONE;
   double spread = 0;

   // 最大10回リトライ
   for(int retry=0; retry<10; retry++)
   {
      RefreshRates();
      
      // スプレッド取得（MT4表示と同じポイント単位）
      spread = MarketInfo(Symbol(), MODE_SPREAD);

      // スプレッドチェック（maxSpreadPoints=0 の場合はスキップ）
      if(maxSpreadPoints > 0 && spread > maxSpreadPoints){
         Print("スプレッド拡大中(", spread,
               "ポイント) → 待機中 (リトライ=", retry+1, ")");
         Sleep(2000);
         continue;
      }

      // エントリー価格と色を決定
      if(orderType == OP_BUY){
         price = Ask;
         clr   = clrBlue;
      }else if(orderType == OP_SELL){
         price = Bid;
         clr   = clrRed;
      }

      ticket = OrderSend(Symbol(), orderType, lots, price,
                         20, sl, tp, orderComment, magic, 0, clr);

      if(ticket > 0){
         Print("新規注文成功! チケットNo=", ticket,
               " レート=", price, " Lots=", lots,
               " スプレッド=", spread, "ポイント");
         return true;
      }else{
         int err = GetLastError();
         Print("新規注文失敗 エラーNo=", err,
               " リトライ回数=", retry+1);
         Sleep(2000);
      }
   }

   return false;
}

//+------------------------------------------------------------------+
//|【関数】全決済関数                                                 |
//|                                                                  |
//|【引数】 orderType : -1=すべて  0=BUYのみ  1=SELLのみ             |
//|【引数】 magic: 対象マジック番号 (-1=全マジック対象)               |
//|【引数】 maxSpreadPoints: 許容スプレッド[Point] (0=制限なし)       |
//|                                                                  |
//|【戻値】true=全成功 false=一部失敗あり                             |
//+------------------------------------------------------------------+
bool funcOrder_CloseAll(int orderType, int magic, int maxSpreadPoints){
   bool allSuccess = true;
   int totalOrders = OrdersTotal();
   double spread, closePrice, lots;
   int type, ticket;
   color  clr    = clrNONE;

   for(int i = totalOrders-1; i >= 0; i--)
   {
      //オーダーセレクト失敗でスキップ
      if(!OrderSelect(i, SELECT_BY_POS, MODE_TRADES)) continue;
      
      // 同一シンボル以外はスキップ
      if(OrderSymbol() != Symbol()) continue;

      // マジック番号指定がある場合は一致しないものをスキップ
      if(magic != -1 && OrderMagicNumber() != magic) continue;

      type   = OrderType();
      ticket = OrderTicket();
      lots   = OrderLots();

      // orderType指定でフィルタ
      if(orderType == 0 && type != OP_BUY) continue;
      if(orderType == 1 && type != OP_SELL) continue;

      // 最大10回リトライ
      bool result = false;
      for(int retry=0; retry<10; retry++)
      {
         RefreshRates();

         // スプレッド取得
         spread = MarketInfo(Symbol(), MODE_SPREAD);

         if(maxSpreadPoints > 0 && spread > maxSpreadPoints){
            Print("スプレッド拡大中(", spread,
                  "ポイント) → クローズ待機中 ticket=", ticket,
                  " リトライ=", retry+1);
            Sleep(2000);
            continue;
         }

         // クローズ価格決定
         if(type == OP_BUY){
            closePrice = Bid;
            clr   = clrBlue;
         }else if(type == OP_SELL){
            closePrice = Ask;
            clr   = clrRed;
         }

         result = OrderClose(ticket, lots, closePrice, 20, clr);

         if(result){
            Print("クローズ成功! チケットNo=", ticket,
                  " ロット=", lots, " クローズ価格=", closePrice,
                  " スプレッド=", spread, "ポイント");
            break;
         }else{
            int err = GetLastError();
            Print("クローズ失敗 ticket=", ticket,
                  " エラーNo=", err,
                  " リトライ=", retry+1);
            Sleep(2000);
         }
      }

      if(!result) allSuccess = false;
   }

   return allSuccess;
}