【MQL4】雇用統計日を自動判別！EAでNFPを回避する関数を解説【ソース付き】

//|【関数】雇用統計判定用関数
//|
//|【引数】 なし
//|
//|【戻値】True:雇用統計日 False:雇用統計日ではない

bool IsKoyouToukeiHantei(){
#define DAYTIME (3600 * 24)
// 曜日
#define SUNDAY 0
#define MONDAY 1
#define TUESDAY 2
#define WEDNESDAY 3
#define THURSDAY 4
#define FRIDAY 5
#define SATURDAY 6

MqlDateTime current;
current.year = Year();
current.mon = Month();
current.day = Day();
current.hour = 12;
current.min = 0 ;
current.sec = 0;

TimeToStruct(StructToTime(current), current);

   //2013年10月と11月は例外
   if(current.year == 2013 && (current.mon == 10 || current.mon == 11)){
      // 2013年10月は22日に発表
      if( current.mon == 10 && current.day == 22 )
      {
         return true;
      }
      // 2013年11月は8日に発表
      if( current.mon == 11 && current.day == 8 )
      {
         return true;
      }      
   }

   else if( current.mon == 1 )
   {
      // 1月は４～１０日の金曜日が雇用統計日
      if( 4 <= current.day && current.day <= 10 && current.day_of_week == FRIDAY )
      {
         return true;
      }
   }
   else if( current.mon == 7 && (current.day == 2 || current.day == 3) && current.day_of_week == THURSDAY)
   {
      return true;
   }
   // 7/4は独立記念日で、日が重なれば木曜日にずれる(7/3が金曜日の場合も振替休日のためずれる)
   else if( current.mon == 7 && (current.day == 3 || current.day == 4) && current.day_of_week == FRIDAY)
   {
      return false;
   }
   else if(  1 <= current.day && current.day <= 10 && (current.day_of_week == THURSDAY || current.day_of_week == FRIDAY ))
   {
      //前の月の12日を含む週から3番目
      MqlDateTime beforeMonth;
      beforeMonth.year = current.year;
      beforeMonth.mon = current.mon - 1;
      beforeMonth.day = 12;
      beforeMonth.hour = 12;
      beforeMonth.min = 0;
      beforeMonth.sec = 0;

      datetime beforeMonthTime = StructToTime(beforeMonth);
      TimeToStruct( beforeMonthTime, beforeMonth);

      datetime emplymentDay = beforeMonthTime + (5 - TimeDayOfWeek(beforeMonthTime) + 21) * DAYTIME;

      if( current.day == TimeDay(emplymentDay) )
      {
         return true;
      }
   }
   return false;
}

//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
{

   //米雇用統計回避
   if(IsKoyouToukeiHantei()==true && Hour() >= 10 && Hour() <= 16){
       //雇用統計日の上記時間帯(開始3時間半前～発表後30分)は処理せず終わる
       return; 
   }

   //以降は普段の処理

}