MT4 EAの作り方｜ボリンジャーバンドで順張りするEAを作る方法

//+------------------------------------------------------------------+
//|                                            02_BollingerBands.mq4 |
//|                                Copyright © 2020-2026 ぷろぐらむFX |
//|                                             https://fx-prog.com/ |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2020-2026 ぷろぐらむFX"
#property link      "https://fx-prog.com/"
#property version   "1.00"
#property strict
input double Lots = 0.01;              //ロット
input int TP = 100;                    //利確(pips)
input int SL = 100;                    //損切り(pips)
//***【パラメータ設定↓】***//
input int BB_KIKAN = 20;               //ボリンジャーバンド期間
//***【パラメータ設定↑】***//
int waitBB = 0;                        //0=待機なし / 1=BUY待機 / -1=SELL待機
string Ea_Name = WindowExpertName();   //EA名称をオーダーコメントに使用
double PipValue;                       //ブローカー桁数に対応したPoint補正
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit(){
   if(Digits == 3 || Digits == 5){
      PipValue = Point * 10;
   }else{
      PipValue = Point;
   }
   return(INIT_SUCCEEDED);
}
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick(){
   //ポジション保有中は新規判定を行わない
   if(OrdersTotal() > 0){
      waitBB = 0;
      return;
   }
   int ea_order_Type = -1;
   double ea_order_stop_price = 0;
   double ea_order_good_price = 0;
//***【新規注文判断↓】***//
   //現在足のボリンジャーバンドを取得
   double BB3UP = iBands(NULL,0,BB_KIKAN,3,0,PRICE_CLOSE,MODE_UPPER,0);
   double BB3LO = iBands(NULL,0,BB_KIKAN,3,0,PRICE_CLOSE,MODE_LOWER,0);
   double BB2UP = iBands(NULL,0,BB_KIKAN,2,0,PRICE_CLOSE,MODE_UPPER,0);
   double BB2LO = iBands(NULL,0,BB_KIKAN,2,0,PRICE_CLOSE,MODE_LOWER,0);
   //3σを突破した方向を記録
   if(Ask > BB3UP){
      waitBB = 1;
   }else if(Bid < BB3LO){
      waitBB = -1;
   }
   //3σ突破後、価格が±2σの内側へ戻ったら同方向へエントリー
   bool inside2Sigma = (Ask < BB2UP && Bid > BB2LO);
   if(waitBB == 1 && inside2Sigma){
      ea_order_Type = OP_BUY;
   }else if(waitBB == -1 && inside2Sigma){
      ea_order_Type = OP_SELL;
   }
//***【新規注文判断↑】***//
//***【TP/SL判断↓】***//
   if(ea_order_Type == OP_BUY){
      ea_order_stop_price = Ask - SL * PipValue;
      ea_order_good_price = Ask + TP * PipValue;
   }else if(ea_order_Type == OP_SELL){
      ea_order_stop_price = Bid + SL * PipValue;
      ea_order_good_price = Bid - TP * PipValue;
   }
//***【TP/SL判断↑】***//
   if(ea_order_Type > -1){
      bool orderResult = funcOrder_Send(ea_order_Type,ea_order_stop_price,ea_order_good_price,Lots,Ea_Name,0,0);
      //注文成功後に待機状態を解除
      if(orderResult){
         waitBB = 0;
      }
   }
}
//★★★★★★★★★★★★★★★★★★★★ ここから下は共通関数 ★★★★★★★★★★★★★★★★★★★★
//+------------------------------------------------------------------+
//|【関数】新規注文関数                                              |
//|【引数】orderType:売買(0=BUY, 1=SELL)                            |
//|【引数】sl:損切り価格  tp:利確価格                               |
//|【引数】lots:取引ロット数                                         |
//|【引数】orderComment:オーダーコメント                             |
//|【引数】magic:MagicNumber                                         |
//|【引数】maxSpreadPoints:許容スプレッド[Point] (0=制限なし)       |
//|【戻値】true=成功 false=失敗                                      |
//+------------------------------------------------------------------+
bool funcOrder_Send(int orderType, double sl, double tp, double lots, string orderComment, int magic, int maxSpreadPoints){
   int ticket = -1;
   double price = 0;
   double spread = 0;
   color clr = clrNONE;
   //最大10回リトライ
   for(int retry=0; retry<10; retry++){
      RefreshRates();
      spread = MarketInfo(Symbol(),MODE_SPREAD);
      //スプレッドチェック
      if(maxSpreadPoints > 0 && spread > maxSpreadPoints){
         Print("スプレッド拡大中(",spread,"ポイント) → 待機中 (リトライ=",retry+1,")");
         Sleep(2000);
         continue;
      }
      //注文価格を取得
      if(orderType == OP_BUY){
         price = Ask;
         clr = clrBlue;
      }else if(orderType == OP_SELL){
         price = Bid;
         clr = clrRed;
      }else{
         Print("funcOrder_Send: 未対応の注文種別=",orderType);
         return false;
      }
      price = NormalizeDouble(price,Digits);
      if(sl > 0) sl = NormalizeDouble(sl,Digits);
      if(tp > 0) tp = NormalizeDouble(tp,Digits);
      ResetLastError();
      ticket = OrderSend(Symbol(),orderType,lots,price,20,sl,tp,orderComment,magic,0,clr);
      if(ticket > 0){
         Print("新規注文成功! チケットNo=",ticket," レート=",price," Lots=",lots," スプレッド=",spread,"ポイント");
         return true;
      }
      int err = GetLastError();
      Print("新規注文失敗 エラーNo=",err," リトライ回数=",retry+1);
      Sleep(2000);
   }
   return false;
}

if(Ask > BB3UP){
   ea_order_Type = OP_BUY;
}else if(Bid < BB3LO){
   ea_order_Type = OP_SELL;
}