MT4 EAの作り方｜ADXで順張りEAを作る方法

//+------------------------------------------------------------------+
//|                                                       29_ADX.mq4 |
//|                                Copyright © 2020-2026 ぷろぐらむFX |
//|                                             https://fx-prog.com/ |
//+------------------------------------------------------------------+

#property copyright "Copyright © 2020-2026 ぷろぐらむFX"
#property link      "https://fx-prog.com/"
#property version   "1.00"
#property strict

input double Lots = 0.01;
input int TP = 100;
input int SL = 100;

//***【パラメータ設定↓】***//
input int ADX_KIKAN = 14;              //ADX期間
input int ADX_ENTRY_SIKII = 25;        //ADXしきい値
//***【パラメータ設定↑】***//

string Ea_Name = WindowExpertName();
double PipValue;
datetime prevtime;

int OnInit(){
   if(Digits == 3 || Digits == 5){
      PipValue = Point * 10;
   }else{
      PipValue = Point;
   }
   return(INIT_SUCCEEDED);
}

void OnTick(){
   if(Time[0] != prevtime){
      prevtime = Time[0];
   }else{
      return;
   }

   int total = OrdersTotal();
   int ea_order_Type = -1;
   double ea_order_stop_price = 0;
   double ea_order_good_price = 0;

   if(total == 0){
      bool openBuy = false;
      bool openSell = false;

      //***【新規注文判断↓】***//
      double ADX_1 = iADX(NULL,0,ADX_KIKAN,PRICE_CLOSE,MODE_MAIN,1);
      double PlusDI_1 = iADX(NULL,0,ADX_KIKAN,PRICE_CLOSE,MODE_PLUSDI,1);
      double MinusDI_1 = iADX(NULL,0,ADX_KIKAN,PRICE_CLOSE,MODE_MINUSDI,1);

      double PlusDI_2 = iADX(NULL,0,ADX_KIKAN,PRICE_CLOSE,MODE_PLUSDI,2);
      double MinusDI_2 = iADX(NULL,0,ADX_KIKAN,PRICE_CLOSE,MODE_MINUSDI,2);

      if(ADX_1 >= ADX_ENTRY_SIKII && PlusDI_2 < MinusDI_2 && PlusDI_1 > MinusDI_1){
         openBuy = true;
      }else if(ADX_1 >= ADX_ENTRY_SIKII && MinusDI_2 < PlusDI_2 && MinusDI_1 > PlusDI_1){
         openSell = true;
      }
      //***【新規注文判断↑】***//

      if(openBuy){
         ea_order_Type = OP_BUY;
      }else if(openSell){
         ea_order_Type = OP_SELL;
      }

      //***【TP/SL判断↓】***//
      if(openBuy){
         ea_order_stop_price = Ask - SL * PipValue;
         ea_order_good_price = Ask + TP * PipValue;
      }else if(openSell){
         ea_order_stop_price = Bid + SL * PipValue;
         ea_order_good_price = Bid - TP * PipValue;
      }
      //***【TP/SL判断↑】***//

      if(ea_order_Type > -1){
         funcOrder_Send(ea_order_Type,ea_order_stop_price,ea_order_good_price,Lots,Ea_Name,0,0);
      }
   }
}


//★★★★★★★★★★★★★★★★★★★★ ここから下は共通関数 ★★★★★★★★★★★★★★★★★★★★

//+------------------------------------------------------------------+
//|【関数】新規注文関数                                              |
//|【引数】orderType:売買(0=BUY, 1=SELL)                            |
//|【引数】sl:損切り価格  tp:利確価格                               |
//|【引数】lots:取引ロット数                                         |
//|【引数】orderComment:オーダーコメント                             |
//|【引数】magic:MagicNumber                                         |
//|【引数】maxSpreadPoints:許容スプレッド[Point] (0=制限なし)       |
//|【戻値】true=成功 false=失敗                                      |
//+------------------------------------------------------------------+
bool funcOrder_Send(int orderType, double sl, double tp, double lots, string orderComment, int magic, int maxSpreadPoints){

   int ticket = -1;
   double price = 0;
   double spread = 0;
   color clr = clrNONE;

   for(int retry=0; retry<10; retry++){

      RefreshRates();
      spread = MarketInfo(Symbol(),MODE_SPREAD);

      if(maxSpreadPoints > 0 && spread > maxSpreadPoints){
         Print("スプレッド拡大中(",spread,"ポイント) → 待機中 (リトライ=",retry+1,")");
         Sleep(2000);
         continue;
      }

      if(orderType == OP_BUY){
         price = Ask;
         clr = clrBlue;
      }else if(orderType == OP_SELL){
         price = Bid;
         clr = clrRed;
      }else{
         Print("funcOrder_Send: 未対応の注文種別=",orderType);
         return false;
      }

      price = NormalizeDouble(price,Digits);

      if(sl > 0) sl = NormalizeDouble(sl,Digits);
      if(tp > 0) tp = NormalizeDouble(tp,Digits);

      ResetLastError();

      ticket = OrderSend(Symbol(),orderType,lots,price,20,sl,tp,orderComment,magic,0,clr);

      if(ticket > 0){
         Print("新規注文成功! チケットNo=",ticket," レート=",price," Lots=",lots," スプレッド=",spread,"ポイント");
         return true;
      }

      int err = GetLastError();
      Print("新規注文失敗 エラーNo=",err," リトライ回数=",retry+1);
      Sleep(2000);
   }

   return false;
}