MT4 EAの作り方｜移動平均線（MA）で順張りするEAを作る方法

//+------------------------------------------------------------------+
//|                                             01_MovingAverage.mq4 |
//|                                Copyright © 2020-2026 ぷろぐらむFX |
//|                                             https://fx-prog.com/ |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2020-2026 ぷろぐらむFX"
#property link      "https://fx-prog.com/"
#property version   "1.00"
#property strict

input double Lots = 0.01;              //ロット

//***【パラメータ設定↓】***//

input int FasterMA = 21;               //短期移動平均線期間
input int MediumMA = 84;               //中期移動平均線期間
input int MAMode = 1;                  //0=SMA 1=EMA 2=SMMA 3=LWMA
input int SL_GOSA = 6;                 //中期MAからSLまでの距離(pips)

//***【パラメータ設定↑】***//

string Ea_Name = WindowExpertName();   //EA名称をオーダーコメントに使用
double PipValue;                       //ブローカー桁数に対応したPoint補正
datetime prevtime;                     //ローソク足時間保持用

//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit(){

   if(Digits == 3 || Digits == 5){
      PipValue = Point * 10;
   }else{
      PipValue = Point;
   }

   return(INIT_SUCCEEDED);
}

//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick(){

   //新しいローソク足ができたときだけ処理
   if(Time[0] != prevtime){
      prevtime = Time[0];
   }else{
      return;
   }

   int total = OrdersTotal();
   int ea_order_Type = -1;
   double ea_order_stop_price = 0;
   double ea_order_good_price = 0;

   //ポジションがない場合は新規エントリー判定
   if(total == 0){

      bool openBuy = false;
      bool openSell = false;

//***【新規注文判断↓】***//

      //1本前・2本前の確定足からMAを取得
      double fasterMA_1 = iMA(NULL,0,FasterMA,0,MAMode,PRICE_CLOSE,1);
      double fasterMA_2 = iMA(NULL,0,FasterMA,0,MAMode,PRICE_CLOSE,2);
      double mediumMA_1 = iMA(NULL,0,MediumMA,0,MAMode,PRICE_CLOSE,1);
      double mediumMA_2 = iMA(NULL,0,MediumMA,0,MAMode,PRICE_CLOSE,2);

      //ゴールデンクロス＋短期MAが上向き
      if(fasterMA_1 > mediumMA_1 && fasterMA_2 < mediumMA_2 && fasterMA_1 > fasterMA_2){
         openBuy = true;

      //デッドクロス＋短期MAが下向き
      }else if(fasterMA_1 < mediumMA_1 && fasterMA_2 > mediumMA_2 && fasterMA_1 < fasterMA_2){
         openSell = true;
      }

//***【新規注文判断↑】***//

      if(openBuy){
         ea_order_Type = OP_BUY;
      }else if(openSell){
         ea_order_Type = OP_SELL;
      }

//***【TP/SL判断↓】***//

      //中期MAを基準にSLを設定し、SL幅と1:1でTPを設定
      double risk = 0;

      if(openBuy){
         ea_order_stop_price = mediumMA_1 - SL_GOSA * PipValue;
         risk = MathAbs(Ask - ea_order_stop_price);
         ea_order_good_price = Ask + risk;
      }else if(openSell){
         ea_order_stop_price = mediumMA_1 + SL_GOSA * PipValue;
         risk = MathAbs(ea_order_stop_price - Bid);
         ea_order_good_price = Bid - risk;
      }

//***【TP/SL判断↑】***//

      if(ea_order_Type > -1){
         //学習用サンプルではMagicNumber管理を行わないため0
         funcOrder_Send(ea_order_Type,ea_order_stop_price,ea_order_good_price,Lots,Ea_Name,0,0);
      }
   }
}


//★★★★★★★★★★★★★★★★★★★★ ここから下は共通関数 ★★★★★★★★★★★★★★★★★★★★

//+------------------------------------------------------------------+
//|【関数】新規注文関数                                              |
//|【引数】orderType:売買(0=BUY, 1=SELL)                            |
//|【引数】sl:損切り価格  tp:利確価格                               |
//|【引数】lots:取引ロット数                                         |
//|【引数】orderComment:オーダーコメント                             |
//|【引数】magic:MagicNumber                                         |
//|【引数】maxSpreadPoints:許容スプレッド[Point] (0=制限なし)       |
//|【戻値】true=成功 false=失敗                                      |
//+------------------------------------------------------------------+
bool funcOrder_Send(int orderType, double sl, double tp, double lots, string orderComment, int magic, int maxSpreadPoints){

   int ticket = -1;
   double price = 0;
   double spread = 0;
   color clr = clrNONE;

   //最大10回リトライ
   for(int retry=0; retry<10; retry++){

      RefreshRates();
      spread = MarketInfo(Symbol(),MODE_SPREAD);

      //スプレッドチェック
      if(maxSpreadPoints > 0 && spread > maxSpreadPoints){
         Print("スプレッド拡大中(",spread,"ポイント) → 待機中 (リトライ=",retry+1,")");
         Sleep(2000);
         continue;
      }

      //注文価格を取得
      if(orderType == OP_BUY){
         price = Ask;
         clr = clrBlue;
      }else if(orderType == OP_SELL){
         price = Bid;
         clr = clrRed;
      }else{
         Print("funcOrder_Send: 未対応の注文種別=",orderType);
         return false;
      }

      price = NormalizeDouble(price,Digits);

      if(sl > 0) sl = NormalizeDouble(sl,Digits);
      if(tp > 0) tp = NormalizeDouble(tp,Digits);

      ResetLastError();

      ticket = OrderSend(Symbol(),orderType,lots,price,20,sl,tp,orderComment,magic,0,clr);

      if(ticket > 0){
         Print("新規注文成功! チケットNo=",ticket," レート=",price," Lots=",lots," スプレッド=",spread,"ポイント");
         return true;
      }

      int err = GetLastError();
      Print("新規注文失敗 エラーNo=",err," リトライ回数=",retry+1);
      Sleep(2000);
   }

   return false;
}