MT4 EAテンプレート｜無料配布＆カスタマイズ解説【MQL4初心者向け】

//+------------------------------------------------------------------+
//|                                                      00_BASE.mq4 |
//|                                Copyright © 2020-2026 ぷろぐらむFX |
//|                                             https://fx-prog.com/ |
//|                                                                  |
//| 使い方：                                                         |
//| 「パラメータ設定」「新規注文判断」「TP/SL判断」「決済注文判断」に |
//| 必要なロジックを追加してEAを作成します。                         |
//+------------------------------------------------------------------+

#property copyright "Copyright © 2020-2026 ぷろぐらむFX"
#property link      "https://fx-prog.com/"
#property version   "1.00"
#property strict


input double Lots = 0.01;              //ロット
input int TP = 100;                    //利確(pips)
input int SL = 100;                    //損切り(pips)


//***【パラメータ設定↓】***//

// ここに個別EAで使用するパラメータを追加してください。

//***【パラメータ設定↑】***//


string Ea_Name = WindowExpertName();   //EA名称をオーダーコメントに使用
double PipValue;                       //ブローカー桁数に対応したPoint補正
datetime prevtime;                     //ローソク足時間保持用


//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit(){

   //3桁・5桁ブローカーのpips補正
   if(Digits == 3 || Digits == 5){
      PipValue = Point * 10;
   }else{
      PipValue = Point;
   }

   return(INIT_SUCCEEDED);
}


//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick(){

   //新しいローソク足ができたときだけ処理
   if(Time[0] != prevtime){
      prevtime = Time[0];
   }else{
      return;
   }

   int total = OrdersTotal();
   int ea_order_Type = -1;
   double ea_order_stop_price = 0;
   double ea_order_good_price = 0;


   //===============================================================
   // ポジションがない場合：新規エントリー判定
   //===============================================================
   if(total == 0){

      bool openBuy = false;
      bool openSell = false;


//***【新規注文判断↓】***//

// BUY・SELL条件を追加してください。
// 条件成立時に openBuy または openSell を true にします。

//***【新規注文判断↑】***//


      if(openBuy){
         ea_order_Type = OP_BUY;
      }else if(openSell){
         ea_order_Type = OP_SELL;
      }


//***【TP/SL判断↓】***//

      //標準では固定pipsのTP・SL
      //個別EAで独自の決済価格を使う場合は、この部分を差し替えます。

      if(openBuy){
         ea_order_stop_price = Ask - SL * PipValue;
         ea_order_good_price = Ask + TP * PipValue;
      }else if(openSell){
         ea_order_stop_price = Bid + SL * PipValue;
         ea_order_good_price = Bid - TP * PipValue;
      }

//***【TP/SL判断↑】***//


      if(ea_order_Type > -1){
         //学習用テンプレートではMagicNumber管理を行わないため0
         funcOrder_Send(ea_order_Type,ea_order_stop_price,ea_order_good_price,Lots,Ea_Name,0,0);
      }


   //===============================================================
   // ポジションがある場合：決済判定
   //===============================================================
   }else{

      bool closeBuy = false;
      bool closeSell = false;


//***【決済注文判断↓】***//

// 決済シグナルを使う場合は条件を追加してください。
// 条件成立時に closeBuy または closeSell を true にします。
// TP・SLだけで決済するEAの場合は何も追加しません。

//***【決済注文判断↑】***//


      if(closeBuy){
         ea_order_Type = OP_BUY;
      }else if(closeSell){
         ea_order_Type = OP_SELL;
      }


      if(ea_order_Type > -1){
         //MagicNumber管理を行わないため全MagicNumberを対象
         funcOrder_CloseAll(ea_order_Type,-1,0);
      }
   }
}


//★★★★★★★★★★★★★★★★★★★★ ここから下は共通関数 ★★★★★★★★★★★★★★★★★★★★


//+------------------------------------------------------------------+
//|【関数】新規注文関数                                              |
//|【引数】orderType:売買(0=BUY, 1=SELL)                            |
//|【引数】sl:損切り価格  tp:利確価格                               |
//|【引数】lots:取引ロット数                                         |
//|【引数】orderComment:オーダーコメント                             |
//|【引数】magic:MagicNumber                                         |
//|【引数】maxSpreadPoints:許容スプレッド[Point] (0=制限なし)       |
//|【戻値】true=成功 false=失敗                                      |
//+------------------------------------------------------------------+
bool funcOrder_Send(int orderType, double sl, double tp, double lots, string orderComment, int magic, int maxSpreadPoints){

   int ticket = -1;
   double price = 0;
   double spread = 0;
   color clr = clrNONE;

   //最大10回リトライ
   for(int retry=0; retry<10; retry++){

      RefreshRates();
      spread = MarketInfo(Symbol(),MODE_SPREAD);

      //スプレッドチェック
      if(maxSpreadPoints > 0 && spread > maxSpreadPoints){
         Print("スプレッド拡大中(",spread,"ポイント) → 待機中 (リトライ=",retry+1,")");
         Sleep(2000);
         continue;
      }

      //注文価格を取得
      if(orderType == OP_BUY){
         price = Ask;
         clr = clrBlue;
      }else if(orderType == OP_SELL){
         price = Bid;
         clr = clrRed;
      }else{
         Print("funcOrder_Send: 未対応の注文種別=",orderType);
         return false;
      }

      price = NormalizeDouble(price,Digits);

      if(sl > 0) sl = NormalizeDouble(sl,Digits);
      if(tp > 0) tp = NormalizeDouble(tp,Digits);

      ResetLastError();

      ticket = OrderSend(Symbol(),orderType,lots,price,20,sl,tp,orderComment,magic,0,clr);

      if(ticket > 0){
         Print("新規注文成功! チケットNo=",ticket," レート=",price," Lots=",lots," スプレッド=",spread,"ポイント");
         return true;
      }

      int err = GetLastError();
      Print("新規注文失敗 エラーNo=",err," リトライ回数=",retry+1);
      Sleep(2000);
   }

   return false;
}


//+------------------------------------------------------------------+
//|【関数】変更注文関数                                              |
//|【引数】ticket:修正対象のチケットNo                              |
//|【引数】sl:新しい損切り価格  tp:新しい利確価格                   |
//|【引数】maxSpreadPoints:許容スプレッド[Point] (0=制限なし)       |
//|【戻値】true=成功 false=失敗                                      |
//+------------------------------------------------------------------+
bool funcOrder_Modify(int ticket, double sl, double tp, int maxSpreadPoints){

   double spread = 0;

   //注文選択
   if(!OrderSelect(ticket,SELECT_BY_TICKET)){
      Print("funcOrder_Modify: OrderSelect失敗 ticket=",ticket," エラー=",GetLastError());
      return false;
   }

   //現在チャートと異なる通貨は変更しない
   if(OrderSymbol() != Symbol()){
      Print("funcOrder_Modify: シンボル不一致 ",OrderSymbol(),"≠",Symbol());
      return false;
   }

   if(sl > 0) sl = NormalizeDouble(sl,Digits);
   if(tp > 0) tp = NormalizeDouble(tp,Digits);

   //最大10回リトライ
   for(int retry=0; retry<10; retry++){

      RefreshRates();
      spread = MarketInfo(Symbol(),MODE_SPREAD);

      //スプレッドチェック
      if(maxSpreadPoints > 0 && spread > maxSpreadPoints){
         Print("スプレッド拡大中(",spread,"ポイント) → 修正待機中 (リトライ=",retry+1,")");
         Sleep(2000);
         continue;
      }

      ResetLastError();

      bool result = OrderModify(ticket,OrderOpenPrice(),sl,tp,0,clrNONE);

      if(result){
         Print("変更注文成功! チケットNo=",ticket," 新SL=",sl," 新TP=",tp," スプレッド=",spread,"ポイント");
         return true;
      }

      int err = GetLastError();
      Print("変更注文失敗 ticket=",ticket," エラーNo=",err," リトライ回数=",retry+1);
      Sleep(2000);
   }

   return false;
}


//+------------------------------------------------------------------+
//|【関数】全決済関数                                                |
//|【引数】orderType:-1=すべて 0=BUYのみ 1=SELLのみ                 |
//|【引数】magic:対象MagicNumber (-1=全MagicNumber)                  |
//|【引数】maxSpreadPoints:許容スプレッド[Point] (0=制限なし)       |
//|【戻値】true=全成功 false=一部失敗あり                            |
//+------------------------------------------------------------------+
bool funcOrder_CloseAll(int orderType, int magic, int maxSpreadPoints){

   bool allSuccess = true;

   //後ろから順番に処理
   for(int i=OrdersTotal()-1; i>=0; i--){

      if(!OrderSelect(i,SELECT_BY_POS,MODE_TRADES)) continue;

      //現在チャートと異なる通貨は対象外
      if(OrderSymbol() != Symbol()) continue;

      //MagicNumber指定がある場合
      if(magic != -1 && OrderMagicNumber() != magic) continue;

      int type = OrderType();

      //成行BUY・SELL以外は対象外
      if(type != OP_BUY && type != OP_SELL) continue;

      //BUY・SELL指定
      if(orderType == OP_BUY && type != OP_BUY) continue;
      if(orderType == OP_SELL && type != OP_SELL) continue;
      if(orderType != -1 && orderType != OP_BUY && orderType != OP_SELL) continue;

      int ticket = OrderTicket();
      double lots = OrderLots();
      bool result = false;

      //最大10回リトライ
      for(int retry=0; retry<10; retry++){

         RefreshRates();

         double spread = MarketInfo(Symbol(),MODE_SPREAD);

         //スプレッドチェック
         if(maxSpreadPoints > 0 && spread > maxSpreadPoints){
            Print("スプレッド拡大中(",spread,"ポイント) → クローズ待機中 ticket=",ticket," リトライ=",retry+1);
            Sleep(2000);
            continue;
         }

         double closePrice = 0;
         color clr = clrNONE;

         if(type == OP_BUY){
            closePrice = Bid;
            clr = clrBlue;
         }else{
            closePrice = Ask;
            clr = clrRed;
         }

         closePrice = NormalizeDouble(closePrice,Digits);
         ResetLastError();

         result = OrderClose(ticket,lots,closePrice,20,clr);

         if(result){
            Print("クローズ成功! チケットNo=",ticket," ロット=",lots," クローズ価格=",closePrice," スプレッド=",spread,"ポイント");
            break;
         }

         int err = GetLastError();
         Print("クローズ失敗 ticket=",ticket," エラーNo=",err," リトライ=",retry+1);
         Sleep(2000);
      }

      if(!result) allSuccess = false;
   }

   return allSuccess;
}

//***【パラメータ設定↓】***//

// ここに個別EAで使用するパラメータを追加してください。

//***【パラメータ設定↑】***//

//***【パラメータ設定↓】***//

input int FasterMA = 21;      //短期移動平均線期間
input int MediumMA = 84;      //中期移動平均線期間
input int MAMode = 1;         //0=SMA 1=EMA 2=SMMA 3=LWMA
input int SL_GOSA = 6;        //中期MAからSLまでの距離(pips)

//***【パラメータ設定↑】***//

//***【新規注文判断↓】***//

// BUY・SELL条件を追加してください。
// 条件成立時に openBuy または openSell を true にします.

//***【新規注文判断↑】***//

//***【TP/SL判断↓】***//

if(openBuy){
   ea_order_stop_price = Ask - SL * PipValue;
   ea_order_good_price = Ask + TP * PipValue;
}else if(openSell){
   ea_order_stop_price = Bid + SL * PipValue;
   ea_order_good_price = Bid - TP * PipValue;
}

//***【TP/SL判断↑】***//

//***【決済注文判断↓】***//

// 決済シグナルを使う場合は条件を追加してください。
// 条件成立時に closeBuy または closeSell を true にします.

//***【決済注文判断↑】***//