MT4で移動平均線（MA）EAを作成｜無料MQL4サンプルコード解説

//+------------------------------------------------------------------+
//|                                             01_MovingAverage.mq4 |
//|                                   Copyright © 2020-2025 ぷろぐらむFX |
//|                                             https://fx-prog.com/ |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2020-2025 ぷろぐらむFX"
#property link      "https://fx-prog.com/"
#property version   "1.00"
#property strict


input double Lots = 0.01;              //ロット
input int TP = 100;                    //利確(pips)
input int SL = 100;                    //損切り(pips)
//***【パラメータ設定↓】***//
input int FasterMA = 21;      //短期移動平均線期間
input int MediumMA = 84;      //中期移動平均線期間
input int MAMode = 1;         //移動平均線種別 0 = sma, 1 = ema, 2 = smma, 3 = lwma
input int SL_GOSA = 6;       //決済時SLライン(pips)
//***【パラメータ設定↑】***//

string Ea_Name = "MovingAverage";      //オーダーコメントに使用

double PipValue;                       //ブローカー桁数に対応した Point 補正
datetime prevtime;                     //ローソク足時間保持用
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit(){

   //デジットチェック
   if (Digits == 3 || Digits == 5){
      PipValue = Point * 10;   // 例: EURUSD 1.23456 → 1pip = 0.00010
   }else{
      PipValue = Point;        // 例: USDJPY 123.45 → 1pip = 0.01
   }

   return(INIT_SUCCEEDED);
}
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason){

}
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick(){

   int total = OrdersTotal();    //ポジショントータル数をセット  
   int ea_order_Type = -1; //0:OP_BUY  1:OP_SELL
   double ea_order_stop_price = 0; //ストップロスレート
   double ea_order_good_price = 0; //利確レート

   //新しい足ができた時だけやる
   if(Time[0] != prevtime){
      prevtime = Time[0];
   }else{
      return;
   }

   //ポジションがない場合はエントリー判定
   if(total == 0){

      bool openBuy  = false;    //買い新規注文判断
      bool openSell = false;    //売り新規注文判断
      
//***【新規注文判断↓】***//
      bool isBullMovingAve_S = false;
      bool isBearMovingAve_S = false;

      //----MA短期値取得      
      double fasterMA_ATAI_1   = iMA(NULL, 0, FasterMA, 0, MAMode, PRICE_CLOSE, 1);    //短期移動平均線で1つ前の値を取得
      double fasterMA_ATAI_2   = iMA(NULL, 0, FasterMA, 0, MAMode, PRICE_CLOSE, 2);    //短期移動平均線で2つ前の値を取得
          
      //----MA中期値取得  
      double MediumMA_ATAI_1   = iMA(NULL, 0, MediumMA, 0, MAMode, PRICE_CLOSE, 1);    //中期移動平均線で1つ前の値を取得
      double MediumMA_ATAI_2   = iMA(NULL, 0, MediumMA, 0, MAMode, PRICE_CLOSE, 2);    //中期移動平均線で2つ前の値を取得 
   
      //MAのゴールデンクロスでロング（短期MAが上を向いている事）  
      if(fasterMA_ATAI_1 > MediumMA_ATAI_1 && fasterMA_ATAI_2 < MediumMA_ATAI_2 && fasterMA_ATAI_1 > fasterMA_ATAI_2){
         isBullMovingAve_S=true;
      }
      //MAのデッドクロスでショート（短期MAが下を向いている事）     
      else if(fasterMA_ATAI_1 < MediumMA_ATAI_1 && fasterMA_ATAI_2 > MediumMA_ATAI_2 && fasterMA_ATAI_1 < fasterMA_ATAI_2){
         isBearMovingAve_S=true;
      }

//***【新規注文判断↑】***//

      //参照するサンプルEAの買いエントリーフラグをセットしてください
      if(isBullMovingAve_S){
         openBuy =true;
         ea_order_Type = OP_BUY;
      //参照するサンプルEAの売りエントリーフラグをセットしてください      
      }else if(isBearMovingAve_S){
         openSell =true;
         ea_order_Type = OP_SELL;
      }

//***【TP/SL判断↓】***//
      double risk = 0;
      if(openBuy){
         //損切り：中期移動平均線付近(設定で変更可)
         ea_order_stop_price = MediumMA_ATAI_1 - SL_GOSA * PipValue;
         
         // リスク幅：エントリー価格(Ask) から SL までの距離
         risk = MathAbs(Ask - ea_order_stop_price);
         
         // 利確：同じ幅だけ上
         ea_order_good_price = Ask + risk;   
      }else if(openSell){
         ea_order_stop_price = MediumMA_ATAI_1 + SL_GOSA * PipValue;

         // リスク幅：エントリー価格(Bid) から SL までの距離
         risk = MathAbs(ea_order_stop_price - Bid);         
         
         ea_order_good_price = Bid - risk;  
      }
//***【TP/SL判断↑】***//

      if(ea_order_Type > -1){
         funcOrder_Send(ea_order_Type,ea_order_stop_price,ea_order_good_price,Lots,Ea_Name,777,0);
      }
      
   }

   return;
}


//★★★★★★★★★★★★★★★★★★★★ ここから下は共通関数 ★★★★★★★★★★★★★★★★★★★★
//+------------------------------------------------------------------+
//|【関数】新規注文関数
//|
//|【引数】 orderType:売買(0=BUY, 1=SELL)
//|【引数】 sl:損切り価格  tp:利確価格
//|【引数】 lots:取引ロット数
//|【引数】 orderComment:オーダーコメント
//|【引数】 magic:マジックNo
//|【引数】 maxSpreadPips: 許容スプレッド[Point] (0=制限なし)
//|
//|【戻値】true=成功 false=失敗
//+------------------------------------------------------------------+
bool funcOrder_Send(int orderType, double sl, double tp, double lots,
                    string orderComment, int magic, int maxSpreadPoints){
   int    ticket = -1;
   double price  = 0;
   color  clr    = clrNONE;
   double spread = 0;

   // 最大10回リトライ
   for(int retry=0; retry<10; retry++)
   {
      RefreshRates();
      
      // スプレッド取得（MT4表示と同じポイント単位）
      spread = MarketInfo(Symbol(), MODE_SPREAD);

      // スプレッドチェック（maxSpreadPoints=0 の場合はスキップ）
      if(maxSpreadPoints > 0 && spread > maxSpreadPoints){
         Print("スプレッド拡大中(", spread,
               "ポイント) → 待機中 (リトライ=", retry+1, ")");
         Sleep(2000);
         continue;
      }

      // エントリー価格と色を決定
      if(orderType == OP_BUY){
         price = Ask;
         clr   = clrBlue;
      }else if(orderType == OP_SELL){
         price = Bid;
         clr   = clrRed;
      }

      ticket = OrderSend(Symbol(), orderType, lots, price,
                         20, sl, tp, orderComment, magic, 0, clr);

      if(ticket > 0){
         Print("新規注文成功! チケットNo=", ticket,
               " レート=", price, " Lots=", lots,
               " スプレッド=", spread, "ポイント");
         return true;
      }else{
         int err = GetLastError();
         Print("新規注文失敗 エラーNo=", err,
               " リトライ回数=", retry+1);
         Sleep(2000);
      }
   }

   return false;
}