MT4インジケーターをサブウィンドウに表示する方法 MQL4の基本設定

#property strict
#property indicator_separate_window
#property indicator_buffers 1
#property indicator_color1 Red
#property indicator_minimum -1.2
#property indicator_maximum 1.2

input int MACD_FAST_PERIOD   = 12;
input int MACD_SLOW_PERIOD   = 26;
input int MACD_SIGNAL_PERIOD = 9;
input int BarLimit = 1000;

double CrossSignal[];

//+------------------------------------------------------------------+
//| 初期化                                                           |
//+------------------------------------------------------------------+
int OnInit()
{
   SetIndexBuffer(0, CrossSignal);
   ArraySetAsSeries(CrossSignal, true);

   SetIndexStyle(0, DRAW_HISTOGRAM, STYLE_SOLID, 2, clrRed);
   SetIndexLabel(0, "MACD Cross");

   SetLevelValue(0, 0);

   return(INIT_SUCCEEDED);
}

//+------------------------------------------------------------------+
//| メイン処理                                                       |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
{
   if(rates_total < MACD_SLOW_PERIOD + MACD_SIGNAL_PERIOD + 3)
      return(0);

   int limit = MathMin(rates_total - 2, BarLimit);

   for(int i = limit; i >= 1; i--)
   {
      CrossSignal[i] = 0;

      double macd_now = iMACD(NULL, 0,
                              MACD_FAST_PERIOD,
                              MACD_SLOW_PERIOD,
                              MACD_SIGNAL_PERIOD,
                              PRICE_CLOSE,
                              MODE_MAIN,
                              i);

      double sig_now = iMACD(NULL, 0,
                             MACD_FAST_PERIOD,
                             MACD_SLOW_PERIOD,
                             MACD_SIGNAL_PERIOD,
                             PRICE_CLOSE,
                             MODE_SIGNAL,
                             i);

      double macd_prev = iMACD(NULL, 0,
                               MACD_FAST_PERIOD,
                               MACD_SLOW_PERIOD,
                               MACD_SIGNAL_PERIOD,
                               PRICE_CLOSE,
                               MODE_MAIN,
                               i + 1);

      double sig_prev = iMACD(NULL, 0,
                              MACD_FAST_PERIOD,
                              MACD_SLOW_PERIOD,
                              MACD_SIGNAL_PERIOD,
                              PRICE_CLOSE,
                              MODE_SIGNAL,
                              i + 1);

      // MACDがシグナルを下から上へ抜けたら +1
      if(macd_prev <= sig_prev && macd_now > sig_now)
      {
         CrossSignal[i] = 1;
      }
      // MACDがシグナルを上から下へ抜けたら -1
      else if(macd_prev >= sig_prev && macd_now < sig_now)
      {
         CrossSignal[i] = -1;
      }
   }

   CrossSignal[0] = 0;

   return(rates_total);
}